| [ < ] | [ > ] | [ << ] | [ Up ] | [ >> ] | [Top] | [Contents] | [Index] | [ ? ] |
Recall that the sequence type is the union of four other Lisp types: lists, vectors, bit vectors, and strings. In other words, any list is a sequence, any vector is a sequence, any bit vector is a sequence, and any string is a sequence. The common property that all sequences have is that each is an ordered collection of elements.
An array is a single primitive object that has a slot for each elements. All the elements are accessible in constant time, but the length of an existing array cannot be changed. Strings, vectors, and bit vectors are the three types of arrays.
A list is a sequence of elements, but it is not a single primitive object; it is made of cons cells, one cell per element. Finding the nth element requires looking through n cons cells, so elements farther from the beginning of the list take longer to access. But it is possible to add elements to the list, or remove elements.
The following diagram shows the relationship between these types:
___________________________________
| |
| Sequence |
| ______ ______________________ |
| | | | | |
| | List | | Array | |
| | | | ________ _______ | |
| |______| | | | | | | |
| | | Vector | | String| | |
| | |________| |_______| | |
| | __________________ | |
| | | | | |
| | | Bit Vector | | |
| | |__________________| | |
| |______________________| |
|___________________________________|
|
The elements of vectors and lists may be any Lisp objects. The elements of strings are all characters. The elements of bit vectors are the numbers 0 and 1.
| 12.1 Sequences | Functions that accept any kind of sequence. | |
| 12.2 Arrays | Characteristics of arrays in XEmacs Lisp. | |
| 12.3 Functions that Operate on Arrays | Functions specifically for arrays. | |
| 12.4 Vectors | Special characteristics of XEmacs Lisp vectors. | |
| 12.5 Functions That Operate on Vectors | Functions specifically for vectors. | |
| 12.6 Bit Vectors | Special characteristics of XEmacs Lisp bit vectors. | |
| 12.7 Functions That Operate on Bit Vectors | Functions specifically for bit vectors. |
| [ < ] | [ > ] | [ << ] | [ Up ] | [ >> ] | [Top] | [Contents] | [Index] | [ ? ] |
In XEmacs Lisp, a sequence is either a list, a vector, a bit vector, or a string. The common property that all sequences have is that each is an ordered collection of elements. This section describes functions that accept any kind of sequence.
Many of the sequence functions take keyword arguments; see (cl)Keyword Arguments. All keyword arguments are optional and, if specified, may appear in any order.
The :key argument should be passed either nil, or a function of
one argument. This key function is used as a filter through which the
elements of the sequence are seen; for example, (find x y :key #'car)
is similar to (assoc* x y): It searches for an element of the list
whose car equals x, rather than for an element which equals
x itself. If :key is omitted or nil, the filter is
effectively the identity function.
The :test and :test-not arguments should be either nil,
or functions of two arguments. The test function is used to compare two
sequence elements, or to compare a search value with sequence elements. (The
two values are passed to the test function in the same order as the original
sequence function arguments from which they are derived, or, if they both come
from the same sequence, in the same order as they appear in that sequence.)
The :test argument specifies a function which must return true
(non-nil) to indicate a match; instead, you may use :test-not to
give a function which returns false to indicate a match. The default
test function is :test 'eql.
Many functions which take item and :test or :test-not
arguments also come in -if and -if-not varieties, where a
predicate function is passed instead of item, and sequence
elements match if the predicate returns true on them (or false in the case of
-if-not). For example:
(remove* 0 seq :test #'<=) ≡ (remove-if #'plusp seq) |
to remove all positive numbers, or any characters, from sequence seq.
Some operations can work on a subsequence of the argument sequence; these
function take :start and :end arguments which default to zero
and the length of the sequence, respectively. Only elements between
start (inclusive) and end (exclusive) are affected by the
operation. The end argument may be passed nil to signify the
length of the sequence; otherwise, both start and end must be
integers, with 0 <= start <= end <= (length seq). If
the function takes two sequence arguments, the limits are defined by keywords
:start1 and :end1 for the first, and :start2 and
:end2 for the second.
A few functions accept a :from-end argument, which, if non-nil,
causes the operation to go from right-to-left through the sequence instead of
left-to-right, and a :count argument, which specifies an integer
maximum number of elements to be removed or otherwise processed.
The sequence functions with :test, :test-not, and :key
keyword arguments follow the Common Lisp specification with regard to the
order of processing of the elements of the relevant sequence. This states that
“you may depend on the order in which arguments are given to [the test
function]; this permits the use of non-commutative test functions in a
predictable manner.”
XEmacs calls the test functions in the expected way (e.g. the last element
will be examined first if :from-end was specified), but GNU Emacs may
not do this.
Strings may have extents see section Extents as well as character data. Duplicable extents will be preserved; non-duplicable extents will not be.
Returns t if object is a list, vector, bit vector, or
string, nil otherwise.
Returns a copy of sequence. The copy is the same type of object as the original sequence, and it has the same elements in the same order.
Storing a new element into the copy does not affect the original
sequence, and vice versa. However, the elements of the new
sequence are not copies; they are identical (eq) to the elements
of the original. Therefore, changes made within these elements, as
found via the copied sequence, are also visible in the original
sequence.
If the sequence is a string with extents or text properties, the extents and text properties in the copy are also copied, not shared with the original. (This means that modifying the extents or text properties of the original will not affect the copy.) However, the actual values of the properties are shared. See section Extents, See section Text Properties.
This is usually equivalent to calling (concatenate (type-of sequence)
sequence), with the exception that copy-sequence handles dotted lists,
which concatenate does not.
See also append in Building Cons Cells and Lists, concat in
Creating Strings, vconcat in Vectors, and
bvconcat in Bit Vectors, for other ways to copy sequences.
(setq bar '(1 2))
⇒ (1 2)
(setq x (vector 'foo bar))
⇒ [foo (1 2)]
(setq y (copy-sequence x))
⇒ [foo (1 2)]
(eq x y)
⇒ nil
(equal x y)
⇒ t
(eq (elt x 1) (elt y 1))
⇒ t
;; Replacing an element of one sequence.
(aset x 0 'quux)
x ⇒ [quux (1 2)]
y ⇒ [foo (1 2)]
;; Modifying the inside of a shared element.
(setcar (aref x 1) 69)
x ⇒ [quux (69 2)]
y ⇒ [foo (69 2)]
;; Creating a bit vector.
(bit-vector 1 0 1 1 0 1 0 0)
⇒ #*10110100
|
Returns the number of elements in sequence. If sequence is
a cons cell that is not a list (because the final CDR is not
nil), a wrong-type-argument error is signaled.
(length '(1 2 3))
⇒ 3
(length ())
⇒ 0
(length "foobar")
⇒ 6
(length [1 2 3])
⇒ 3
(length #*01101)
⇒ 5
|
This function returns the element of sequence indexed by
index. Legitimate values of index are integers ranging from
0 up to one less than the length of sequence. If sequence
is a list, then out-of-range values of index return nil;
otherwise, they trigger an args-out-of-range error.
(elt [1 2 3 4] 2)
⇒ 3
(elt '(1 2 3 4) 2)
⇒ 3
(char-to-string (elt "1234" 2))
⇒ "3"
(elt #*00010000 3)
⇒ 1
(elt [1 2 3 4] 4)
error-->Args out of range: [1 2 3 4], 4
(elt [1 2 3 4] -1)
error-->Args out of range: [1 2 3 4], -1
|
This function generalizes aref (see section Functions that Operate on Arrays) and
nth (see section Accessing Elements of Lists).
This function fills the sequence sequence with object, so
that each element of sequence between the indices specified by
:start (inclusive) and :end (exclusive), is object.
It returns sequence.
(setq a [a b c d e f g])
⇒ [a b c d e f g]
(fill a 0 :end 2)
⇒ [0 0 c d e f g]
(fill a 0)
⇒ [0 0 0 0 0 0 0]
a
⇒ [0 0 0 0 0 0 0]
(setq s "When in the course")
⇒ "When in the course"
(fill s ?-)
⇒ "------------------"
(setq bv #*1101)
⇒ #*1101
(fill bv 0)
⇒ #*0000
|
If sequence is of a type that cannot hold object (
bit-vector can only hold the integers one or zero, strings can only hold
characters) a wrong-type-argument error results.
This function concatenates the argument sequences together to form a result
sequence of type result-type, usually one of the symbols vector,
string, or list. The arguments are always copied, even in cases
such as (concatenate 'list '(1 2 3)) where the result is already of the
desired type.
This function returns a given subsequence of the argument sequence, which may be a list or an array. The indices start and end must be in range, and start must be no greater than end. If end is omitted, it defaults to the length of the sequence. The return value is always a copy; it does not share structure with sequence.
As an extension to Common Lisp, start and/or end may be negative,
in which case they represent a distance back from the end of the sequence.
This is for compatibility with Emacs’ substring function. Note that
subseq is the only sequence function that allows negative
start and end.
You can use setf on a subseq form to replace a specified range
of elements with elements from another sequence. The replacement is done as
if by replace, described below.
This function copies part of seq2 into part of seq1. The sequence seq1 is not stretched or resized; the amount of data copied is simply the shorter of the source and destination (sub)sequences. The function returns seq1.
If seq1 and seq2 are eq, then the replacement will work
correctly even if the regions indicated by the start and end arguments
overlap. However, if seq1 and seq2 are lists which share storage
but are not eq, and the start and end arguments specify overlapping
regions, the effect is undefined.
This returns a copy of seq with all elements matching item
removed. The result may share storage with or be eq to seq in
some circumstances, but the original seq will not be modified. The
:test, :test-not, and :key arguments define the matching
test that is used; by default, elements eql to item are removed.
The :count argument specifies the maximum number of matching elements
that can be removed (only the leftmost count matches are removed). The
:start and :end arguments specify a region in seq in which
elements will be removed; elements outside that region are not matched or
removed. The :from-end argument, if true, says that elements should be
deleted from the end of the sequence rather than the beginning (this matters
only if count was also specified).
This deletes all elements of seq which match item. It is a
destructive operation. Since Emacs Lisp does not support stretchable strings
or vectors, this is the same as remove* for those sequence types. On
lists, remove* will copy the list if necessary to preserve the original
list, whereas delete* will splice out parts of the argument list.
Compare append and nconc, which are analogous non-destructive
and destructive list operations.
The predicate-oriented functions remove-if, remove-if-not,
delete-if, and delete-if-not are defined similarly.
This function deletes (destructively) from list all elements which are
equal to item.
This function removes from list all elements which are equal to
item.
This function removes from list all elements which are eq to
item.
This function returns a copy of seq with duplicate elements removed.
Specifically, if two elements from the sequence match according to the
:test, :test-not, and :key arguments, only the rightmost
one is retained. If :from-end is true, the leftmost one is retained
instead. If :start or :end is specified, only elements within
that subsequence are examined or removed.
This function deletes duplicate elements from seq. It is a destructive
version of remove-duplicates.
This function returns a copy of seq, with all elements matching
old replaced with new. The :count, :start,
:end, and :from-end arguments may be used to limit the number of
substitutions made.
This is a destructive version of substitute; it performs the
substitution using setcar or aset rather than by returning a
changed copy of the sequence.
The substitute-if, substitute-if-not, nsubstitute-if, and
nsubstitute-if-not functions are defined similarly. For these, a
predicate is given in place of the old argument.
| [ < ] | [ > ] | [ << ] | [ Up ] | [ >> ] | [Top] | [Contents] | [Index] | [ ? ] |
An array object has slots that hold a number of other Lisp objects, called the elements of the array. Any element of an array may be accessed in constant time. In contrast, an element of a list requires access time that is proportional to the position of the element in the list.
When you create an array, you must specify how many elements it has. The amount of space allocated depends on the number of elements. Therefore, it is impossible to change the size of an array once it is created; you cannot add or remove elements. However, you can replace an element with a different value.
XEmacs defines three types of array, all of which are one-dimensional: strings, vectors, and bit vectors. A vector is a general array; its elements can be any Lisp objects. A string is a specialized array; its elements must be characters. A bit vector is another specialized array; its elements must be bits (an integer, either 0 or 1). Each type of array has its own read syntax. See section String Type, Vector Type, and Bit Vector Type.
All kinds of array share these characteristics:
aref and aset, respectively (see section Functions that Operate on Arrays).
In principle, if you wish to have an array of text characters, you could use either a string or a vector. In practice, we always choose strings for such applications, for four reasons:
By contrast, for an array of keyboard input characters (such as a key sequence), a vector may be necessary, because many keyboard input characters are non-printable and are represented with symbols rather than with characters. See section Key Sequence Input.
Similarly, when representing an array of bits, a bit vector has the following advantages over a regular vector:
| [ < ] | [ > ] | [ << ] | [ Up ] | [ >> ] | [Top] | [Contents] | [Index] | [ ? ] |
In this section, we describe the functions that accept strings, vectors, and bit vectors.
This function returns t if object is an array (i.e., a
string, vector, or bit vector).
(arrayp "asdf") ⇒ t (arrayp [a]) ⇒ t (arrayp #*101) ⇒ t |
This function returns the indexth element of array. The first element is at index zero.
(setq primes [2 3 5 7 11 13])
⇒ [2 3 5 7 11 13]
(aref primes 4)
⇒ 11
(elt primes 4)
⇒ 11
(aref "abcdefg" 1)
⇒ ?b
(aref #*1101 2)
⇒ 0
|
See also the function elt, in Sequences.
This function sets the indexth element of array to be object. It returns object.
(setq w [foo bar baz])
⇒ [foo bar baz]
(aset w 0 'fu)
⇒ fu
w
⇒ [fu bar baz]
(setq x "asdfasfd")
⇒ "asdfasfd"
(aset x 3 ?Z)
⇒ ?Z
x
⇒ "asdZasfd"
(setq bv #*1111)
⇒ #*1111
(aset bv 2 0)
⇒ 0
bv
⇒ #*1101
|
If array is a string and object is not a character, a
wrong-type-argument error results.
The general sequence functions copy-sequence and length
are often useful for objects known to be arrays. See section Sequences.
| [ < ] | [ > ] | [ << ] | [ Up ] | [ >> ] | [Top] | [Contents] | [Index] | [ ? ] |
Arrays in Lisp, like arrays in most languages, are blocks of memory whose elements can be accessed in constant time. A vector is a general-purpose array; its elements can be any Lisp objects. (The other kind of array in XEmacs Lisp is the string, whose elements must be characters.) Vectors in XEmacs serve as obarrays (vectors of symbols), although this is a shortcoming that should be fixed. They are also used internally as part of the representation of a byte-compiled function; if you print such a function, you will see a vector in it.
In XEmacs Lisp, the indices of the elements of a vector start from zero and count up from there.
Vectors are printed with square brackets surrounding the elements.
Thus, a vector whose elements are the symbols a, b and
a is printed as [a b a]. You can write vectors in the
same way in Lisp input.
A vector, like a string or a number, is considered a constant for evaluation: the result of evaluating it is the same vector. This does not evaluate or even examine the elements of the vector. See section Self-Evaluating Forms.
Here are examples of these principles:
(setq avector [1 two '(three) "four" [five]])
⇒ [1 two (quote (three)) "four" [five]]
(eval avector)
⇒ [1 two (quote (three)) "four" [five]]
(eq avector (eval avector))
⇒ t
|
| [ < ] | [ > ] | [ << ] | [ Up ] | [ >> ] | [Top] | [Contents] | [Index] | [ ? ] |
Here are some functions that relate to vectors:
This function returns t if object is a vector.
(vectorp [a])
⇒ t
(vectorp "asdf")
⇒ nil
|
This function creates and returns a vector whose elements are the arguments, objects.
(vector 'foo 23 [bar baz] "rats")
⇒ [foo 23 [bar baz] "rats"]
(vector)
⇒ []
|
This function returns a new vector consisting of length elements, each initialized to object.
(setq sleepy (make-vector 9 'Z))
⇒ [Z Z Z Z Z Z Z Z Z]
|
This function returns a new vector containing all the elements of the sequences. The arguments sequences may be lists, vectors, or strings. If no sequences are given, an empty vector is returned.
The value is a newly constructed vector that is not eq to any
existing vector.
(setq a (vconcat '(A B C) '(D E F)))
⇒ [A B C D E F]
(eq a (vconcat a))
⇒ nil
(vconcat)
⇒ []
(vconcat [A B C] "aa" '(foo (6 7)))
⇒ [A B C 97 97 foo (6 7)]
|
The vconcat function also allows integers as arguments. It
converts them to strings of digits, making up the decimal print
representation of the integer, and then uses the strings instead of the
original integers. Don’t use this feature; we plan to eliminate
it. If you already use this feature, change your programs now! The
proper way to convert an integer to a decimal number in this way is with
format (see section Formatting Strings) or number-to-string
(see section Conversion of Characters and Strings).
For other concatenation functions, see mapconcat in Mapping Functions, concat in Creating Strings, append
in Building Cons Cells and Lists, and bvconcat in Functions That Operate on Bit Vectors.
The append function provides a way to convert a vector into a
list with the same elements (see section Building Cons Cells and Lists):
(setq avector [1 two (quote (three)) "four" [five]])
⇒ [1 two (quote (three)) "four" [five]]
(append avector nil)
⇒ (1 two (quote (three)) "four" [five])
|
| [ < ] | [ > ] | [ << ] | [ Up ] | [ >> ] | [Top] | [Contents] | [Index] | [ ? ] |
Bit vectors are specialized vectors that can only represent arrays of 1’s and 0’s. Bit vectors have a very efficient representation and are useful for representing sets of boolean (true or false) values.
There is no limit on the size of a bit vector. You could, for example, create a bit vector with 100,000 elements if you really wanted to.
Bit vectors have a special printed representation consisting of ‘#*’ followed by the bits of the vector. For example, a bit vector whose elements are 0, 1, 1, 0, and 1, respectively, is printed as
#*01101 |
Bit vectors are considered constants for evaluation, like vectors, strings, and numbers. See section Self-Evaluating Forms.
| [ < ] | [ > ] | [ << ] | [ Up ] | [ >> ] | [Top] | [Contents] | [Index] | [ ? ] |
Here are some functions that relate to bit vectors:
This function returns t if object is a bit vector.
(bit-vector-p #*01)
⇒ t
(bit-vector-p [0 1])
⇒ nil
(bit-vector-p "01")
⇒ nil
|
This function returns t if object is either 0 or 1.
This function creates and returns a bit vector whose elements are the arguments bits. Each argument must be a bit, i.e. one of the two integers 0 or 1.
(bit-vector 0 0 0 1 0 0 0 0 1 0)
⇒ #*0001000010
(bit-vector)
⇒ #*
|
This function creates and returns a bit vector consisting of length elements, each initialized to bit, which must be one of the two integers 0 or 1.
(setq picket-fence (make-bit-vector 9 1))
⇒ #*111111111
|
This function returns a new bit vector containing all the elements of the sequences. The arguments sequences may be lists, vectors, or bit vectors, all of whose elements are the integers 0 or 1. If no sequences are given, an empty bit vector is returned.
The value is a newly constructed bit vector that is not eq to any
existing bit vector.
(setq a (bvconcat '(1 1 0) '(0 0 1)))
⇒ #*110001
(eq a (bvconcat a))
⇒ nil
(bvconcat)
⇒ #*
(bvconcat [1 0 0 0 0] #*111 '(0 0 0 0 1))
⇒ #*1000011100001
|
For other concatenation functions, see mapconcat in Mapping Functions, concat in Creating Strings, vconcat in
Functions That Operate on Vectors, and append in Building Cons Cells and Lists.
The append function provides a way to convert a bit vector into a
list with the same elements (see section Building Cons Cells and Lists):
(setq bv #*00001110)
⇒ #*00001110
(append bv nil)
⇒ (0 0 0 0 1 1 1 0)
|
| [ << ] | [ >> ] | [Top] | [Contents] | [Index] | [ ? ] |
This document was generated on September 25, 2026 using texi2html 1.82.