42. Markers

A marker is a Lisp object used to specify a position in a buffer relative to the surrounding text. A marker changes its offset from the beginning of the buffer automatically whenever text is inserted or deleted, so that it stays with the two characters on either side of it.

42.1 Overview of Markers

A marker specifies a buffer and a position in that buffer. The marker can be used to represent a position in the functions that require one, just as an integer could be used. See section Positions, for a complete description of positions.

A marker has two attributes: the marker position, and the marker buffer. The marker position is an integer that is equivalent (at a given time) to the marker as a position in that buffer. But the marker’s position value can change often during the life of the marker. Insertion and deletion of text in the buffer relocate the marker. The idea is that a marker positioned between two characters remains between those two characters despite insertion and deletion elsewhere in the buffer. Relocation changes the integer equivalent of the marker.

Deleting text around a marker’s position leaves the marker between the characters immediately before and after the deleted text. Inserting text at the position of a marker normally leaves the marker in front of the new text—unless it is inserted with insert-before-markers (see section Inserting Text).

Insertion and deletion in a buffer must check all the markers and relocate them if necessary. This slows processing in a buffer with a large number of markers. For this reason, it is a good idea to make a marker point nowhere if you are sure you don’t need it any more. Unreferenced markers are garbage collected eventually, but until then will continue to use time if they do point somewhere.

Because it is common to perform arithmetic operations on a marker position, most of the arithmetic operations (including + and -) accept markers as arguments. In such cases, the marker stands for its current position.

Note that you can use extents to achieve the same functionality, and more, as markers. (Markers were defined before extents, which is why they both continue to exist.) A zero-length extent with the detachable property removed is almost identical to a marker. (See section Extent Endpoints, for more information on zero-length extents.)

In particular:

• In order to get marker-like behavior in a zero-length extent, the detachable property must be removed (otherwise, the extent will disappear when text near it is deleted) and exactly one endpoint must be closed (if both endpoints are closed, the extent will expand to contain text inserted where it is located).
• If a zero-length extent has the end-open property but not the start-open property (this is the default), text inserted at the extent’s location causes the extent to move forward, just like a marker.
• If a zero-length extent has the start-open property but not the end-open property, text inserted at the extent’s location causes the extent to remain before the text, like what happens to markers when insert-before-markers is used.
• Markers end up after or before inserted text depending on whether insert or insert-before-markers was called. These functions do not affect zero-length extents differently; instead, the presence or absence of the start-open and end-open extent properties determines this, as just described.
• Markers are automatically removed from a buffer when they are no longer in use. Extents remain around until explicitly removed from a buffer.
• Many functions are provided for listing the extents in a buffer or in a region of a buffer. No such functions exist for markers.

Here are examples of creating markers, setting markers, and moving point to markers:

;; Make a new marker that initially does not point anywhere:
(setq m1 (make-marker))
     ⇒ #<marker in no buffer>

;; Set m1 to point between the 99th and 100th characters
;;   in the current buffer:
(set-marker m1 100)
     ⇒ #<marker at 100 in markers.texi>

;; Now insert one character at the beginning of the buffer:
(goto-char (point-min))
     ⇒ 1
(insert "Q")
     ⇒ nil

;; m1 is updated appropriately.
m1
     ⇒ #<marker at 101 in markers.texi>

;; Two markers that point to the same position
;;   are not eq, but they are equal.
(setq m2 (copy-marker m1))
     ⇒ #<marker at 101 in markers.texi>
(eq m1 m2)
     ⇒ nil
(equal m1 m2)
     ⇒ t

;; When you are finished using a marker, make it point nowhere.
(set-marker m1 nil)
     ⇒ #<marker in no buffer>

42.2 Predicates on Markers

You can test an object to see whether it is a marker, or whether it is either an integer or a marker or either an integer, a character, or a marker. The latter tests are useful in connection with the arithmetic functions that work with any of markers, integers, or characters.

Function: markerp object

This function returns t if object is a marker, nil otherwise. Note that integers are not markers, even though many functions will accept either a marker or an integer.

Function: integer-or-marker-p object

This function returns t if object is an integer or a marker, nil otherwise.

Function: integer-char-or-marker-p object

This function returns t if object is an integer, a character, or a marker, nil otherwise.

Function: number-or-marker-p object

This function returns t if object is a number (either kind) or a marker, nil otherwise.

Function: number-char-or-marker-p object

This function returns t if object is a number (either kind), a character, or a marker, nil otherwise.

42.3 Functions That Create Markers

When you create a new marker, you can make it point nowhere, or point to the present position of point, or to the beginning or end of the accessible portion of the buffer, or to the same place as another given marker.

Function: make-marker

This functions returns a newly created marker that does not point anywhere.

(make-marker) ⇒ #<marker in no buffer>

Function: point-marker &optional dont-copy-p buffer

This function returns a marker that points to the present position of point in buffer, which defaults to the current buffer. See section Point. For an example, see copy-marker, below.

Internally, a marker corresponding to point is always maintained. Normally the marker returned by point-marker is a copy; you may modify it with reckless abandon. However, if optional argument dont-copy-p is non-nil, then the real point-marker is returned; modifying the position of this marker will move point. It is illegal to change the buffer of it, or make it point nowhere.

Function: point-min-marker &optional buffer

This function returns a new marker that points to the beginning of the accessible portion of buffer, which defaults to the current buffer. This will be the beginning of the buffer unless narrowing is in effect. See section Narrowing.

Function: point-max-marker &optional buffer

This function returns a new marker that points to the end of the accessible portion of buffer, which defaults to the current buffer. This will be the end of the buffer unless narrowing is in effect. See section Narrowing.

Here are examples of this function and point-min-marker, shown in a buffer containing a version of the source file for the text of this chapter.

(point-min-marker) ⇒ #<marker at 1 in markers.texi> (point-max-marker) ⇒ #<marker at 15573 in markers.texi> (narrow-to-region 100 200) ⇒ nil (point-min-marker) ⇒ #<marker at 100 in markers.texi> (point-max-marker) ⇒ #<marker at 200 in markers.texi>

Function: copy-marker marker-or-integer &optional marker-type

If passed a marker as its argument, copy-marker returns a new marker that points to the same place and the same buffer as does marker-or-integer. If passed an integer as its argument, copy-marker returns a new marker that points to position marker-or-integer in the current buffer.

If passed an integer argument less than 1, copy-marker returns a new marker that points to the beginning of the current buffer. If passed an integer argument greater than the length of the buffer, copy-marker returns a new marker that points to the end of the buffer.

An error is signaled if marker-or-integer is neither a marker nor an integer.

Optional second argument marker-type specifies the insertion type of the new marker; see marker-insertion-type.

(setq p (point-marker)) ⇒ #<marker at 2139 in markers.texi> (setq q (copy-marker p)) ⇒ #<marker at 2139 in markers.texi> (eq p q) ⇒ nil (equal p q) ⇒ t (point) ⇒ 2139 (set-marker p 3000) ⇒ #<marker at 3000 in markers.texi> (point) ⇒ 2139 (setq p (point-marker t)) ⇒ #<marker at 2139 in markers.texi> (set-marker p 3000) ⇒ #<marker at 3000 in markers.texi> (point) ⇒ 3000 (copy-marker 0) ⇒ #<marker at 1 in markers.texi> (copy-marker 20000) ⇒ #<marker at 7572 in markers.texi>

42.4 Information from Markers

This section describes the functions for accessing the components of a marker object.

Function: marker-position marker

This function returns the position that marker points to, or nil if it points nowhere.

Function: marker-buffer marker

This function returns the buffer that marker points into, or nil if it points nowhere.

(setq m (make-marker)) ⇒ #<marker in no buffer> (marker-position m) ⇒ nil (marker-buffer m) ⇒ nil (set-marker m 3770 (current-buffer)) ⇒ #<marker at 3770 in markers.texi> (marker-buffer m) ⇒ #<buffer markers.texi> (marker-position m) ⇒ 3770

Two distinct markers are considered equal (even though not eq) to each other if they have the same position and buffer, or if they both point nowhere.

42.5 Changing Marker Positions

This section describes how to change the position of an existing marker. When you do this, be sure you know whether the marker is used outside of your program, and, if so, what effects will result from moving it—otherwise, confusing things may happen in other parts of Emacs.

Function: set-marker marker position &optional buffer

This function moves marker to position in buffer. If buffer is not provided, it defaults to the current buffer.

position can be a marker, an integer or nil. If position is an integer, set-marker moves marker to point before the positionth character in buffer. If position is nil, marker is made to point nowhere. Then it no longer slows down editing in any buffer. If position is less than 1, marker is moved to the beginning of buffer. If position is greater than the size of buffer, marker is moved to the end of buffer.

The value returned is marker.

(setq m (point-marker)) ⇒ #<marker at 4714 in markers.texi> (set-marker m 55) ⇒ #<marker at 55 in markers.texi> (setq b (get-buffer "foo")) ⇒ #<buffer foo> (set-marker m 0 b) ⇒ #<marker at 1 in foo>

Function: move-marker marker position &optional buffer

This is another name for set-marker.

42.6 The Mark

One special marker in each buffer is designated the mark. It records a position for the user for the sake of commands such as C-w and C-x <TAB>. Lisp programs should set the mark only to values that have a potential use to the user, and never for their own internal purposes. For example, the replace-regexp command sets the mark to the value of point before doing any replacements, because this enables the user to move back there conveniently after the replace is finished.

Once the mark “exists” in a buffer, it normally never ceases to exist. However, it may become inactive, and usually does so after each command (other than simple motion commands and some commands that explicitly activate the mark). When the mark is active, the region between point and the mark is called the active region and is highlighted specially.

Many commands are designed so that when called interactively they operate on the text between point and the mark. Such commands work only when an active region exists, i.e. when the mark is active. (The reason for this is to prevent you from accidentally deleting or changing large chunks of your text.) If you are writing such a command, don’t examine the mark directly; instead, use interactive with the ‘r’ specification. This provides the values of point and the mark as arguments to the command in an interactive call, but permits other Lisp programs to specify arguments explicitly, and automatically signals an error if the command is called interactively when no active region exists. See section Code Characters for interactive.

Each buffer has its own value of the mark that is independent of the value of the mark in other buffers. (When a buffer is created, the mark exists but does not point anywhere. We consider this state as “the absence of a mark in that buffer.”) However, only one active region can exist at a time. Activating the mark in one buffer automatically deactivates an active mark in any other buffer. Note that the user can explicitly activate a mark at any time by using the command activate-region (normally bound to M-C-z) or by using the command exchange-point-and-mark (normally bound to C-x C-x), which has the side effect of activating the mark.

Some people do not like active regions, so they disable this behavior by setting the variable zmacs-regions to nil. This makes the mark always active (except when a buffer is just created and the mark points nowhere), and turns off the highlighting of the region between point and the mark. Commands that explicitly retrieve the value of the mark should make sure that they behave correctly and consistently irrespective of the setting of zmacs-regions; some primitives are provided to ensure this behavior.

In addition to the mark, each buffer has a mark ring which is a list of markers containing previous values of the mark. When editing commands change the mark, they should normally save the old value of the mark on the mark ring. The variable mark-ring-max specifies the maximum number of entries in the mark ring; once the list becomes this long, adding a new element deletes the last element.

Function: mark &optional force buffer

This function returns buffer’s mark position as an integer. buffer defaults to the current buffer if omitted.

If the mark is inactive, mark normally returns nil. However, if force is non-nil, then mark returns the mark position anyway—or nil, if the mark is not yet set for the buffer.

(Remember that if zmacs-regions is nil, the mark is always active as long as it exists, and the force argument will have no effect.)

If you are using this in an editing command, you are most likely making a mistake; see the documentation of set-mark below.

Function: mark-marker &optional force buffer

This function returns buffer’s mark. buffer defaults to the current buffer if omitted. This is the very marker that records the mark location inside XEmacs, not a copy. Therefore, changing this marker’s position will directly affect the position of the mark. Don’t do it unless that is the effect you want.

If the mark is inactive, mark-marker normally returns nil. However, if force is non-nil, then mark-marker returns the mark anyway.

(setq m (mark-marker)) ⇒ #<marker at 3420 in markers.texi> (set-marker m 100) ⇒ #<marker at 100 in markers.texi> (mark-marker) ⇒ #<marker at 100 in markers.texi>

Like any marker, this marker can be set to point at any buffer you like. We don’t recommend that you make it point at any buffer other than the one of which it is the mark. If you do, it will yield perfectly consistent, but rather odd, results.

Function: set-mark position &optional buffer

This function sets buffer’s mark to position, and activates the mark. buffer defaults to the current buffer if omitted. The old value of the mark is not pushed onto the mark ring.

Please note: Use this function only if you want the user to see that the mark has moved, and you want the previous mark position to be lost. Normally, when a new mark is set, the old one should go on the mark-ring. For this reason, most applications should use push-mark and pop-mark, not set-mark.

Novice XEmacs Lisp programmers often try to use the mark for the wrong purposes. The mark saves a location for the user’s convenience. An editing command should not alter the mark unless altering the mark is part of the user-level functionality of the command. (And, in that case, this effect should be documented.) To remember a location for internal use in the Lisp program, store it in a Lisp variable. For example:

(let ((start (point))) (forward-line 1) (delete-region start (point))).

Command: exchange-point-and-mark &optional dont-activate-region

This function exchanges the positions of point and the mark. It is intended for interactive use. The mark is also activated unless dont-activate-region is non-nil.

Function: push-mark &optional position nomsg activate buffer

This function sets buffer’s mark to position, and pushes a copy of the previous mark onto mark-ring. buffer defaults to the current buffer if omitted. If position is nil, then the value of point is used. push-mark returns nil.

If the last global mark pushed was not in buffer, also push position on the global mark ring (see below).

The function push-mark normally does not activate the mark. To do that, specify t for the argument activate.

A ‘Mark set’ message is displayed unless nomsg is non-nil.

Function: pop-mark

This function pops off the top element of mark-ring and makes that mark become the buffer’s actual mark. This does not move point in the buffer, and it does nothing if mark-ring is empty. It deactivates the mark.

The return value is not meaningful.

Variable: mark-ring

The value of this buffer-local variable is the list of saved former marks of the current buffer, most recent first.

mark-ring ⇒ (#<marker at 11050 in markers.texi> #<marker at 10832 in markers.texi> …)

User Option: mark-ring-max

The value of this variable is the maximum size of mark-ring. If more marks than this are pushed onto the mark-ring, push-mark discards an old mark when it adds a new one.

In additional to a per-buffer mark ring, there is a global mark ring. Marks are pushed onto the global mark ring the first time you set a mark after switching buffers.

Variable: global-mark-ring

The value of this variable is the list of saved former global marks, most recent first.

User Option: mark-ring-max

The value of this variable is the maximum size of global-mark-ring. If more marks than this are pushed onto the global-mark-ring, push-mark discards an old mark when it adds a new one.

Command: pop-global-mark

This function pops a mark off the global mark ring and jumps to that location.

This document was generated by Aidan Kehoe on December 27, 2016 using texi2html 1.82.