56. Processes

In the terminology of operating systems, a process is a space in which a program can execute. XEmacs runs in a process. XEmacs Lisp programs can invoke other programs in processes of their own. These are called subprocesses or child processes of the XEmacs process, which is their parent process.

A subprocess of XEmacs may be synchronous or asynchronous, depending on how it is created. When you create a synchronous subprocess, the Lisp program waits for the subprocess to terminate before continuing execution. When you create an asynchronous subprocess, it can run in parallel with the Lisp program. This kind of subprocess is represented within XEmacs by a Lisp object which is also called a “process”. Lisp programs can use this object to communicate with the subprocess or to control it. For example, you can send signals, obtain status information, receive output from the process, or send input to it.

Function: processp object

This function returns t if object is a process, nil otherwise.

56.1 Functions that Create Subprocesses

There are three functions that create a new subprocess in which to run a program. One of them, start-process, creates an asynchronous process and returns a process object (see section Creating an Asynchronous Process). The other two, call-process and call-process-region, create a synchronous process and do not return a process object (see section Creating a Synchronous Process).

Synchronous and asynchronous processes are explained in the following sections. Since the three functions are all called in a similar fashion, their common arguments are described here.

In all cases, the function’s program argument specifies the program to be run. An error is signaled if the file is not found or cannot be executed. If the file name is relative, the variable exec-path contains a list of directories to search. Emacs initializes exec-path when it starts up, based on the value of the environment variable PATH. The standard file name constructs, ‘~’, ‘.’, and ‘..’, are interpreted as usual in exec-path, but environment variable substitutions (‘$HOME’, etc.) are not recognized; use substitute-in-file-name to perform them (see section Functions that Expand Filenames).

Each of the subprocess-creating functions has a buffer-or-name argument which specifies where the standard output from the program will go. If buffer-or-name is nil, that says to discard the output unless a filter function handles it. (See section Process Filter Functions, and Reading and Printing Lisp Objects.) Normally, you should avoid having multiple processes send output to the same buffer because their output would be intermixed randomly.

All three of the subprocess-creating functions have a &rest argument, args. The args must all be strings, and they are supplied to program as separate command line arguments. Wildcard characters and other shell constructs are not allowed in these strings, since they are passed directly to the specified program.

Please note: The argument program contains only the name of the program; it may not contain any command-line arguments. You must use args to provide those.

If you want to use features of the shell, then invoke the shell directly using, for example, program of "sh", and args of "-c" and "command line...".

The subprocess gets its current directory from the value of default-directory (see section Functions that Expand Filenames).

The subprocess inherits its environment from XEmacs; but you can specify overrides for it with process-environment. See section Operating System Environment.

Variable: exec-directory

The value of this variable is the name of a directory (a string) that contains programs that come with XEmacs, that are intended for XEmacs to invoke. The program etags is an example of such a program.

User Option: exec-path

The value of this variable is a list of directories to search for programs to run in subprocesses. Each element is either the name of a directory (i.e., a string), or nil, which stands for the default directory (which is the value of default-directory).

The value of exec-path is used by call-process and start-process when the program argument is not an absolute file name.

56.2 Creating a Synchronous Process

After a synchronous process is created, XEmacs waits for the process to terminate before continuing. Starting Dired is an example of this: it runs ls in a synchronous process, then modifies the output slightly. Because the process is synchronous, the entire directory listing arrives in the buffer before XEmacs tries to do anything with it.

While Emacs waits for the synchronous subprocess to terminate, the user can quit by typing C-g. The first C-g tries to kill the subprocess with a SIGINT signal; but it waits until the subprocess actually terminates before quitting. If during that time the user types another C-g, that kills the subprocess instantly with SIGKILL and quits immediately. See section Quitting.

The synchronous subprocess functions returned nil in version 18. In version 19, they return an indication of how the process terminated.

Function: call-process program &optional infile destination display &rest args

This function calls program in a separate process and waits for it to finish.

The standard input for the process comes from file infile if infile is not nil and from ‘/dev/null’ otherwise. The argument destination says where to put the process output. Here are the possibilities:

a buffer

Insert the output in that buffer, before point. This includes both the standard output stream and the standard error stream of the process.

a string

Find or create a buffer with that name, then insert the output in that buffer, before point.

t

Insert the output in the current buffer, before point.

nil

Discard the output.

0

Discard the output, and return immediately without waiting for the subprocess to finish.

In this case, the process is not truly synchronous, since it can run in parallel with Emacs; but you can think of it as synchronous in that Emacs is essentially finished with the subprocess as soon as this function returns.

(real-destination error-destination)

Keep the standard output stream separate from the standard error stream; deal with the ordinary output as specified by real-destination, and dispose of the error output according to error-destination. The value nil means discard it, t means mix it with the ordinary output, and a string specifies a file name to redirect error output into.

You can’t directly specify a buffer to put the error output in; that is too difficult to implement. But you can achieve this result by sending the error output to a temporary file and then inserting the file into a buffer.

If display is non-nil, then call-process redisplays the buffer as output is inserted. Otherwise the function does no redisplay, and the results become visible on the screen only when XEmacs redisplays that buffer in the normal course of events.

The remaining arguments, args, are strings that specify command line arguments for the program.

The value returned by call-process (unless you told it not to wait) indicates the reason for process termination. A number gives the exit status of the subprocess; 0 means success, and any other value means failure. If the process terminated with a signal, call-process returns a string describing the signal.

In the examples below, the buffer ‘foo’ is current.

(call-process "pwd" nil t) ⇒ nil ---------- Buffer: foo ---------- /usr/user/lewis/manual ---------- Buffer: foo ---------- (call-process "grep" nil "bar" nil "lewis" "/etc/passwd") ⇒ nil ---------- Buffer: bar ---------- lewis:5LTsHm66CSWKg:398:21:Bil Lewis:/user/lewis:/bin/csh ---------- Buffer: bar ----------

The insert-directory function contains a good example of the use of call-process:

(call-process insert-directory-program nil t nil switches (if full-directory-p (concat (file-name-as-directory file) ".") file))

Function: call-process-region start end program &optional deletep destination displayp &rest args

This function sends the text between start to end as standard input to a process running program. It deletes the text sent if deletep is non-nil; this is useful when buffer is t, to insert the output in the current buffer.

The arguments destination and displayp control what to do with the output from the subprocess, and whether to update the display as it comes in. For details, see the description of call-process, above. If destination is the integer 0, call-process-region discards the output and returns nil immediately, without waiting for the subprocess to finish.

The remaining arguments, args, are strings that specify command line arguments for the program.

The return value of call-process-region is just like that of call-process: nil if you told it to return without waiting; otherwise, a number or string which indicates how the subprocess terminated.

In the following example, we use call-process-region to run the cat utility, with standard input being the first five characters in buffer ‘foo’ (the word ‘input’). cat copies its standard input into its standard output. Since the argument destination is t, this output is inserted in the current buffer.

---------- Buffer: foo ---------- input∗ ---------- Buffer: foo ---------- (call-process-region 1 6 "cat" nil t) ⇒ nil ---------- Buffer: foo ---------- inputinput∗ ---------- Buffer: foo ----------

The shell-command-on-region command uses call-process-region like this:

(call-process-region start end shell-file-name ; Name of program. nil ; Do not delete region. buffer ; Send output to buffer. nil ; No redisplay during output. "-c" command) ; Arguments for the shell.

56.3 MS-DOS Subprocesses

On MS-DOS, you must indicate whether the data going to and from a synchronous subprocess are text or binary. Text data requires translation between the end-of-line convention used within Emacs (a single newline character) and the convention used outside Emacs (the two-character sequence, CRLF).

The variable binary-process-input applies to input sent to the subprocess, and binary-process-output applies to output received from it. A non-nil value means the data is non-text; nil means the data is text, and calls for conversion.

Variable: binary-process-input

If this variable is nil, convert newlines to CRLF sequences in the input to a synchronous subprocess.

Variable: binary-process-output

If this variable is nil, convert CRLF sequences to newlines in the output from a synchronous subprocess.

See section Files and MS-DOS, for related information.

56.4 Creating an Asynchronous Process

After an asynchronous process is created, Emacs and the Lisp program both continue running immediately. The process may thereafter run in parallel with Emacs, and the two may communicate with each other using the functions described in following sections. Here we describe how to create an asynchronous process with start-process.

Function: start-process name buffer-or-name program &rest args

This function creates a new asynchronous subprocess and starts the program program running in it. It returns a process object that stands for the new subprocess in Lisp. The argument name specifies the name for the process object; if a process with this name already exists, then name is modified (by adding ‘<1>’, etc.) to be unique. The buffer buffer-or-name is the buffer to associate with the process.

The remaining arguments, args, are strings that specify command line arguments for the program.

In the example below, the first process is started and runs (rather, sleeps) for 100 seconds. Meanwhile, the second process is started, and given the name ‘my-process<1>’ for the sake of uniqueness. It inserts the directory listing at the end of the buffer ‘foo’, before the first process finishes. Then it finishes, and a message to that effect is inserted in the buffer. Much later, the first process finishes, and another message is inserted in the buffer for it.

(start-process "my-process" "foo" "sleep" "100") ⇒ #<process my-process> (start-process "my-process" "foo" "ls" "-l" "/user/lewis/bin") ⇒ #<process my-process<1>> ---------- Buffer: foo ---------- total 2 lrwxrwxrwx 1 lewis 14 Jul 22 10:12 gnuemacs --> /emacs -rwxrwxrwx 1 lewis 19 Jul 30 21:02 lemon Process my-process<1> finished Process my-process finished ---------- Buffer: foo ----------

Function: start-process-shell-command name buffer-or-name command &rest command-args

This function is like start-process except that it uses a shell to execute the specified command. The argument command is a shell command name, and command-args are the arguments for the shell command.

Variable: process-connection-type

This variable controls the type of device used to communicate with asynchronous subprocesses. If it is non-nil, then PTYs are used, when available. Otherwise, pipes are used.

PTYs are usually preferable for processes visible to the user, as in Shell mode, because they allow job control (C-c, C-z, etc.) to work between the process and its children whereas pipes do not. For subprocesses used for internal purposes by programs, it is often better to use a pipe, because they are more efficient. In addition, the total number of PTYs is limited on many systems and it is good not to waste them. A rule of thumb is to use ptys for processes the user interacts with directly, and pipes for processes that are hidden from the user.

The value process-connection-type is used when start-process is called. So you can specify how to communicate with one subprocess by binding the variable around the call to start-process.

(let ((process-connection-type nil)) ; Use a pipe. (start-process …))

To determine whether a given subprocess actually got a pipe or a PTY, use the function process-tty-name (see section Process Information).

Lisp functions that manipulate processes usually accept a process argument. Besides using an actual process object for this argument, you can use a process name, a buffer object, the name of a buffer, or nil. Specifying a buffer or buffer name for the process argument means use the process associated with the buffer (or the most recent one, if there is more than one). nil means use the process associated with the current buffer. See section Process Information. See section Process Buffers.

56.5 Deleting Processes

Deleting a process disconnects XEmacs immediately from the subprocess, and removes it from the list of active processes. It sends a signal to the subprocess to make the subprocess terminate, but this is not guaranteed to happen immediately. The process object itself continues to exist as long as other Lisp objects point to it.

You can delete a process explicitly at any time. Processes are deleted automatically after they terminate, but not necessarily right away. If you delete a terminated process explicitly before it is deleted automatically, no harm results.

Variable: delete-exited-processes

This variable controls automatic deletion of processes that have terminated (due to calling exit or to a signal). If it is nil, then they continue to exist until the user runs list-processes. Otherwise, they are deleted immediately after they exit.

Function: delete-process name

This function deletes the process associated with name, killing it with a SIGHUP signal. The argument name may be a process, the name of a process, a buffer, or the name of a buffer.

(delete-process "*shell*") ⇒ nil

Function: process-kill-without-query process &optional require-query-p

This function declares that XEmacs need not query the user if process is still running when XEmacs is exited. The process will be deleted silently. If require-query-p is non-nil, then XEmacs will query the user (this is the default). The return value is t if a query was formerly required, and nil otherwise.

(process-kill-without-query (get-process "shell")) ⇒ t

56.6 Process Information

Several functions return information about processes. list-processes is provided for interactive use.

Command: list-processes

This command displays a listing of all living processes. In addition, it finally deletes any process whose status was ‘Exited’ or ‘Signaled’. It returns nil.

Function: process-list

This function returns a list of all processes that have not been deleted.

(process-list) ⇒ (#<process display-time> #<process shell>)

Function: get-process process-name

This function returns the process named process-name. If process-name is a string and there is no process with that name, the value is nil. If process-name is actually a process, it is returned as given. (That is not very useful, so the argument is usually a name.) For example:

(get-process "shell") ⇒ #<process shell>

Function: process-command process

This function returns the command that was executed to start process. This is a list of strings, the first string being the program executed and the rest of the strings being the arguments that were given to the program.

(process-command (get-process "shell")) ⇒ ("/bin/csh" "-i")

Function: process-id process

This function returns the PID of process. This is an integer that distinguishes the process process from all other processes running on the same computer at the current time. The PID of a process is chosen by the operating system kernel when the process is started and remains constant as long as the process exists.

Function: process-name process

This function returns the name of process.

Function: process-status process

This function returns the status of process as a symbol. The argument process must be a process, a buffer, a process name (string) or a buffer name (string).

The possible values for an actual subprocess are:

run

for a process that is running.

stop

for a process that is stopped but continuable.

exit

for a process that has exited.

signal

for a process that has received a fatal signal.

open

for a network connection that is open.

closed

for a network connection that is closed. Once a connection is closed, you cannot reopen it, though you might be able to open a new connection to the same place.

nil

if process does not identify an existing process.

(process-status "shell") ⇒ run (process-status (get-buffer "*shell*")) ⇒ run x ⇒ #<process xx<1>> (process-status x) ⇒ exit

For a network connection, process-status returns one of the symbols open or closed. The latter means that the other side closed the connection, or XEmacs did delete-process.

In earlier Emacs versions (prior to version 19), the status of a network connection was run if open, and exit if closed.

Function: process-kill-without-query-p process

This function returns whether process will be killed without querying the user, if it is running when XEmacs is exited. The default value is nil.

Function: process-exit-status process

This function returns the exit status of process or the signal number that killed it. (Use the result of process-status to determine which of those it is.) If process has not yet terminated, the value is 0.

Function: process-tty-name process

This function returns the terminal name that process is using for its communication with Emacs—or nil if it is using pipes instead of a terminal (see process-connection-type in Creating an Asynchronous Process).

56.7 Sending Input to Processes

Asynchronous subprocesses receive input when it is sent to them by XEmacs, which is done with the functions in this section. You must specify the process to send input to, and the input data to send. The data appears on the “standard input” of the subprocess.

Some operating systems have limited space for buffered input in a PTY. On these systems, XEmacs sends long input in chunks, with EOF characters added amidst the other characters, to force the operating system to periodically drain the input buffer. For most programs, these EOFs do no harm.

Function: process-send-string process string &optional start end

This function sends process the contents of string as standard input.

The argument process may be a process or the name of a process, or a buffer or the name of a buffer, in which case the buffer’s process is used. If it is nil, the current buffer’s process is used.

Optional arguments start and end specify part of string; see subseq.

The function returns nil.

(process-send-string "shell<1>" "ls\n") ⇒ nil ---------- Buffer: *shell* ---------- ... introduction.texi syntax-tables.texi~ introduction.texi~ text.texi introduction.txt text.texi~ ... ---------- Buffer: *shell* ----------

Function: process-send-region process start end &optional buffer

This function sends the text in the region defined by start and end as standard input to process.

The argument process may be a process or the name of a process, or a buffer or the name of a buffer, in which case the buffer’s process is used. If it is nil, the current buffer’s process is used.

An error is signaled unless both start and end are integers or markers that indicate positions in the current buffer. (It is unimportant which number is larger.)

Function: process-send-eof &optional process

This function makes process see an end-of-file in its input. The EOF comes after any text already sent to it.

process may be a process, a buffer, the name of a process or buffer, or nil, indicating the current buffer’s process. An error is signaled if process does not identify any process.

The function returns the process object identified by process.

(process-send-eof "shell") ⇒ "shell"

56.8 Sending Signals to Processes

Sending a signal to a subprocess is a way of interrupting its activities. There are several different signals, each with its own meaning. The set of signals and their names is defined by the operating system. For example, the signal SIGINT means that the user has typed C-c, or that some analogous thing has happened.

Each signal has a standard effect on the subprocess. Most signals kill the subprocess, but some stop or resume execution instead. Most signals can optionally be handled by programs; if the program handles the signal, then we can say nothing in general about its effects.

The set of signals and their names is defined by the operating system; XEmacs has facilities for sending only a few of the signals that are defined. XEmacs can send signals only to its own subprocesses.

You can send signals explicitly by calling the functions in this section. XEmacs also sends signals automatically at certain times: killing a buffer sends a SIGHUP signal to all its associated processes; killing XEmacs sends a SIGHUP signal to all remaining processes. (SIGHUP is a signal that indicates that the connection between the user and the process is broken, for example if a connection via a telephone line is hung up.)

Each of the signal-sending functions takes two optional arguments: process and current-group.

The argument process must be either a process or a buffer, the name of one, or nil. If it is nil, the process defaults to the process associated with the current buffer. An error is signaled if process does not identify a process.

The argument current-group is a flag that makes a difference when you are running a job-control shell as an XEmacs subprocess. If it is non-nil, then the signal is sent to the current foreground process group of the terminal that XEmacs uses to communicate with the subprocess. If the process is a job-control shell, this means the shell’s current subjob. If it is nil, the signal is sent to the process group of the immediate subprocess of XEmacs. If the subprocess is a job-control shell, this is the shell itself.

The flag current-group has no effect when a pipe is used to communicate with the subprocess, because the operating system does not support the distinction in the case of pipes. For the same reason, job-control shells won’t work when a pipe is used. See process-connection-type in Creating an Asynchronous Process.

Some of the functions below take a signal argument, which identifies a signal to be sent. It must be either a fixnum or a symbol which names the signal, like SIGSEGV.

Function: process-send-signal signal &optional process current-group

This function sends the signal signal to the process process. The following functions can be implemented in terms of process-send-signal.

Function: interrupt-process &optional process current-group

This function interrupts the process process by sending the signal SIGINT. Outside of XEmacs, typing the “interrupt character” (normally C-c) sends this signal. When the argument current-group is non-nil, you can think of this function as “typing C-c” on the terminal by which XEmacs talks to the subprocess.

Function: kill-process &optional process current-group

This function kills the process process by sending the signal SIGKILL. This signal kills the subprocess immediately, and cannot be handled by the subprocess.

Function: quit-process &optional process current-group

This function sends the signal SIGQUIT to the process process. This signal is the one sent by the “quit character” (usually C-\) when you are not inside XEmacs.

Function: stop-process &optional process current-group

This function stops the process process by sending the signal SIGTSTP. Use continue-process to resume its execution.

On systems with job control, the “stop character” (usually C-z) sends this signal (outside of XEmacs). When current-group is non-nil, you can think of this function as “typing C-z” on the terminal XEmacs uses to communicate with the subprocess.

Function: continue-process &optional process current-group

This function resumes execution of the process process by sending it the signal SIGCONT. This presumes that process was stopped previously.

Command: signal-process pid signal

This function sends a signal to the process with process id pid, which need not be a child of XEmacs. The argument signal specifies which signal to send.

56.9 Receiving Output from Processes

There are two ways to receive the output that a subprocess writes to its standard output stream. The output can be inserted in a buffer, which is called the associated buffer of the process, or a function called the filter function can be called to act on the output. If the process has no buffer and no filter function, its output is discarded.

56.9.1 Process Buffers

A process can (and usually does) have an associated buffer, which is an ordinary Emacs buffer that is used for two purposes: storing the output from the process, and deciding when to kill the process. You can also use the buffer to identify a process to operate on, since in normal practice only one process is associated with any given buffer. Many applications of processes also use the buffer for editing input to be sent to the process, but this is not built into XEmacs Lisp.

Unless the process has a filter function (see section Process Filter Functions), its output is inserted in the associated buffer. The position to insert the output is determined by the process-mark, which is then updated to point to the end of the text just inserted. Usually, but not always, the process-mark is at the end of the buffer.

Function: process-buffer process

This function returns the associated buffer of the process process.

(process-buffer (get-process "shell")) ⇒ #<buffer *shell*>

Function: process-mark process

This function returns the process marker for process, which is the marker that says where to insert output from the process.

If process does not have a buffer, process-mark returns a marker that points nowhere.

Insertion of process output in a buffer uses this marker to decide where to insert, and updates it to point after the inserted text. That is why successive batches of output are inserted consecutively.

Filter functions normally should use this marker in the same fashion as is done by direct insertion of output in the buffer. A good example of a filter function that uses process-mark is found at the end of the following section.

When the user is expected to enter input in the process buffer for transmission to the process, the process marker is useful for distinguishing the new input from previous output.

Function: set-process-buffer process buffer

This function sets the buffer associated with process to buffer. If buffer is nil, the process becomes associated with no buffer.

Function: get-buffer-process buffer-or-name

This function returns the process associated with buffer-or-name. If there are several processes associated with buffer-or-name, then one is chosen. (Presently, the one chosen is the one most recently created.) It is usually a bad idea to have more than one process associated with the same buffer.

(get-buffer-process "*shell*") ⇒ #<process shell>

Killing the process’s buffer deletes the process, which kills the subprocess with a SIGHUP signal (see section Sending Signals to Processes).

56.9.2 Process Filter Functions

A process filter function is a function that receives the standard output from the associated process. If a process has a filter, then all output from that process is passed to the filter. The process buffer is used directly for output from the process only when there is no filter.

A filter function must accept two arguments: the associated process and a string, which is the output. The function is then free to do whatever it chooses with the output.

A filter function runs only while XEmacs is waiting (e.g., for terminal input, or for time to elapse, or for process output). This avoids the timing errors that could result from running filters at random places in the middle of other Lisp programs. You may explicitly cause Emacs to wait, so that filter functions will run, by calling sit-for or sleep-for (see section Waiting for Elapsed Time or Input), or accept-process-output (see section Accepting Output from Processes). Emacs is also waiting when the command loop is reading input.

Quitting is normally inhibited within a filter function—otherwise, the effect of typing C-g at command level or to quit a user command would be unpredictable. If you want to permit quitting inside a filter function, bind inhibit-quit to nil. See section Quitting.

If an error happens during execution of a filter function, it is caught automatically, so that it doesn’t stop the execution of whatever program was running when the filter function was started. However, if debug-on-error is non-nil, the error-catching is turned off. This makes it possible to use the Lisp debugger to debug the filter function. See section The Lisp Debugger.

Many filter functions sometimes or always insert the text in the process’s buffer, mimicking the actions of XEmacs when there is no filter. Such filter functions need to use set-buffer in order to be sure to insert in that buffer. To avoid setting the current buffer semipermanently, these filter functions must use unwind-protect to make sure to restore the previous current buffer. They should also update the process marker, and in some cases update the value of point. Here is how to do these things:

(defun ordinary-insertion-filter (process string)
  (let ((old-buffer (current-buffer)))
    (unwind-protect
        (let (moving)
          (set-buffer (process-buffer process))
          (setq moving (= (point) (process-mark process)))

          (save-excursion
            ;; Insert the text, moving the process-marker.
            (goto-char (process-mark process))
            (insert string)
            (set-marker (process-mark process) (point)))
          (if moving (goto-char (process-mark process))))
      (set-buffer old-buffer))))

The reason to use an explicit unwind-protect rather than letting save-excursion restore the current buffer is so as to preserve the change in point made by goto-char.

To make the filter force the process buffer to be visible whenever new text arrives, insert the following line just before the unwind-protect:

(display-buffer (process-buffer process))

To force point to move to the end of the new output no matter where it was previously, eliminate the variable moving and call goto-char unconditionally.

In earlier Emacs versions, every filter function that did regexp searching or matching had to explicitly save and restore the match data. Now Emacs does this automatically; filter functions never need to do it explicitly. See section The Match Data.

A filter function that writes the output into the buffer of the process should check whether the buffer is still alive. If it tries to insert into a dead buffer, it will get an error. If the buffer is dead, (buffer-name (process-buffer process)) returns nil.

The output to the function may come in chunks of any size. A program that produces the same output twice in a row may send it as one batch of 200 characters one time, and five batches of 40 characters the next.

Function: set-process-filter process filter

This function gives process the filter function filter. If filter is nil, then the process will have no filter. If filter is t, then no output from the process will be accepted until the filter is changed. (Output received during this time is not discarded, but is queued, and will be processed as soon as the filter is changed.)

Function: process-filter process

This function returns the filter function of process, or nil if it has none. t means that output processing has been stopped.

Here is an example of use of a filter function:

(defun keep-output (process output)
   (setq kept (cons output kept)))
     ⇒ keep-output

(setq kept nil)
     ⇒ nil

(set-process-filter (get-process "shell") 'keep-output)
     ⇒ keep-output

(process-send-string "shell" "ls ~/other\n")
     ⇒ nil
kept
     ⇒ ("lewis@slug[8] % "

"FINAL-W87-SHORT.MSS    backup.otl              kolstad.mss~
address.txt             backup.psf              kolstad.psf
backup.bib~             david.mss               resume-Dec-86.mss~
backup.err              david.psf               resume-Dec.psf
backup.mss              dland                   syllabus.mss
"
"#backups.mss#          backup.mss~             kolstad.mss
")

56.9.3 Accepting Output from Processes

Output from asynchronous subprocesses normally arrives only while XEmacs is waiting for some sort of external event, such as elapsed time or terminal input. Occasionally it is useful in a Lisp program to explicitly permit output to arrive at a specific point, or even to wait until output arrives from a process.

Function: accept-process-output &optional process seconds millisec

This function allows XEmacs to read pending output from processes. The output is inserted in the associated buffers or given to their filter functions. If process is non-nil then this function does not return until some output has been received from process.

The arguments seconds and millisec let you specify timeout periods. The former specifies a period measured in seconds and the latter specifies one measured in milliseconds. The two time periods thus specified are added together, and accept-process-output returns after that much time whether or not there has been any subprocess output. Note that seconds is allowed to be a floating-point number; thus, there is no need to ever use millisec. (It is retained for compatibility purposes.)

The function accept-process-output returns non-nil if it did get some output, or nil if the timeout expired before output arrived.

56.10 Sentinels: Detecting Process Status Changes

A process sentinel is a function that is called whenever the associated process changes status for any reason, including signals (whether sent by XEmacs or caused by the process’s own actions) that terminate, stop, or continue the process. The process sentinel is also called if the process exits. The sentinel receives two arguments: the process for which the event occurred, and a string describing the type of event.

The string describing the event looks like one of the following:

• "finished\n".
• "exited abnormally with code exitcode\n".
• "name-of-signal\n".
• "name-of-signal (core dumped)\n".

A sentinel runs only while XEmacs is waiting (e.g., for terminal input, or for time to elapse, or for process output). This avoids the timing errors that could result from running them at random places in the middle of other Lisp programs. A program can wait, so that sentinels will run, by calling sit-for or sleep-for (see section Waiting for Elapsed Time or Input), or accept-process-output (see section Accepting Output from Processes). Emacs is also waiting when the command loop is reading input.

Quitting is normally inhibited within a sentinel—otherwise, the effect of typing C-g at command level or to quit a user command would be unpredictable. If you want to permit quitting inside a sentinel, bind inhibit-quit to nil. See section Quitting.

A sentinel that writes the output into the buffer of the process should check whether the buffer is still alive. If it tries to insert into a dead buffer, it will get an error. If the buffer is dead, (buffer-name (process-buffer process)) returns nil.

If an error happens during execution of a sentinel, it is caught automatically, so that it doesn’t stop the execution of whatever programs was running when the sentinel was started. However, if debug-on-error is non-nil, the error-catching is turned off. This makes it possible to use the Lisp debugger to debug the sentinel. See section The Lisp Debugger.

In earlier Emacs versions, every sentinel that did regexp searching or matching had to explicitly save and restore the match data. Now Emacs does this automatically; sentinels never need to do it explicitly. See section The Match Data.

Function: set-process-sentinel process sentinel

This function associates sentinel with process. If sentinel is nil, then the process will have no sentinel. The default behavior when there is no sentinel is to insert a message in the process’s buffer when the process status changes.

(defun msg-me (process event) (princ (format "Process: %s had the event `%s'" process event))) (set-process-sentinel (get-process "shell") 'msg-me) ⇒ msg-me (kill-process (get-process "shell")) -| Process: #<process shell> had the event `killed' ⇒ #<process shell>

Function: process-sentinel process

This function returns the sentinel of process, or nil if it has none.

Function: waiting-for-user-input-p

While a sentinel or filter function is running, this function returns non-nil if XEmacs was waiting for keyboard input from the user at the time the sentinel or filter function was called, nil if it was not.

56.11 Process Window Size

Function: set-process-window-size process height width

This function tells process that its logical window size is height by width characters. This is principally useful with pty’s.

56.12 Transaction Queues

You can use a transaction queue for more convenient communication with subprocesses using transactions. First use tq-create to create a transaction queue communicating with a specified process. Then you can call tq-enqueue to send a transaction.

Function: tq-create process

This function creates and returns a transaction queue communicating with process. The argument process should be a subprocess capable of sending and receiving streams of bytes. It may be a child process, or it may be a TCP connection to a server, possibly on another machine.

Function: tq-enqueue queue question regexp closure fn

This function sends a transaction to queue queue. Specifying the queue has the effect of specifying the subprocess to talk to.

The argument question is the outgoing message that starts the transaction. The argument fn is the function to call when the corresponding answer comes back; it is called with two arguments: closure, and the answer received.

The argument regexp is a regular expression that should match the entire answer, but nothing less; that’s how tq-enqueue determines where the answer ends.

The return value of tq-enqueue itself is not meaningful.

Function: tq-close queue

Shut down transaction queue queue, waiting for all pending transactions to complete, and then terminate the connection or child process.

Transaction queues are implemented by means of a filter function. See section Process Filter Functions.

This document was generated by Aidan Kehoe on December 27, 2016 using texi2html 1.82.