[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [Top] [Contents] [Index] [ ? ]

33. Major and Minor Modes

A mode is a set of definitions that customize XEmacs and can be turned on and off while you edit. There are two varieties of modes: major modes, which are mutually exclusive and used for editing particular kinds of text, and minor modes, which provide features that users can enable individually.

This chapter describes how to write both major and minor modes, how to indicate them in the modeline, and how they run hooks supplied by the user. For related topics such as keymaps and syntax tables, see 26. Keymaps, and 45. Syntax Tables.

33.1 Major Modes  Defining major modes.
33.2 Minor Modes  Defining minor modes.
33.3 Modeline Format  Customizing the text that appears in the modeline.
33.4 Hooks  How to use hooks; how to write code that provides hooks.


[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [Top] [Contents] [Index] [ ? ]

33.1 Major Modes

Major modes specialize XEmacs for editing particular kinds of text. Each buffer has only one major mode at a time. For each major mode there is a function to switch to that mode in the current buffer; its name should end in `-mode'. These functions work by setting buffer-local variable bindings and other data associated with the buffer, such as a local keymap. The effect lasts until you switch to another major mode in the same buffer.

The least specialized major mode is called Fundamental mode. This mode has no mode-specific definitions or variable settings, so each XEmacs command behaves in its default manner, and each option is in its default state. All other major modes redefine various keys and options. For example, Lisp Interaction mode provides special key bindings for LFD (eval-print-last-sexp), TAB (lisp-indent-line), and other keys.

When you need to write several editing commands to help you perform a specialized editing task, creating a new major mode is usually a good idea. In practice, writing a major mode is easy (in contrast to writing a minor mode, which is often difficult).

If the new mode is similar to an old one, it is often unwise to modify the old one to serve two purposes, since it may become harder to use and maintain. Instead, copy and rename an existing major mode definition and alter the copy--or define a derived mode (see section 33.1.5 Defining Derived Modes). For example, Rmail Edit mode, which is in `emacs/lisp/rmailedit.el', is a major mode that is very similar to Text mode except that it provides three additional commands. Its definition is distinct from that of Text mode, but was derived from it.

Even if the new mode is not an obvious derivative of any other mode, it is convenient to use define-derived-mode with a nil parent argument, since it automatically enforces the most important coding conventions for you.

Rmail Edit mode is an example of a case where one piece of text is put temporarily into a different major mode so it can be edited in a different way (with ordinary XEmacs commands rather than Rmail). In such cases, the temporary major mode usually has a command to switch back to the buffer's usual mode (Rmail mode, in this case). You might be tempted to present the temporary redefinitions inside a recursive edit and restore the usual ones when the user exits; but this is a bad idea because it constrains the user's options when it is done in more than one buffer: recursive edits must be exited most-recently-entered first. Using alternative major modes avoids this limitation. See section 25.10 Recursive Editing.

The standard XEmacs Lisp library directory contains the code for several major modes, in files including `text-mode.el', `texinfo.el', `lisp-mode.el', `c-mode.el', and `rmail.el'. You can look at these libraries to see how modes are written. Text mode is perhaps the simplest major mode aside from Fundamental mode. Rmail mode is a complicated and specialized mode.

33.1.1 Major Mode Conventions  Coding conventions for keymaps, etc.
33.1.2 Major Mode Examples  Text mode and Lisp modes.
33.1.3 How XEmacs Chooses a Major Mode  How XEmacs chooses the major mode automatically.
33.1.4 Getting Help about a Major Mode  Finding out how to use a mode.
33.1.5 Defining Derived Modes  Defining a new major mode based on another major mode.


[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [Top] [Contents] [Index] [ ? ]

33.1.1 Major Mode Conventions

The code for existing major modes follows various coding conventions, including conventions for local keymap and syntax table initialization, global names, and hooks. Please follow these conventions when you define a new major mode:

Variable: change-major-mode-hook
This normal hook is run by kill-all-local-variables before it does anything else. This gives major modes a way to arrange for something special to be done if the user switches to a different major mode. For best results, make this variable buffer-local, so that it will disappear after doing its job and will not interfere with the subsequent major mode. See section 33.4 Hooks.


[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [Top] [Contents] [Index] [ ? ]

33.1.2 Major Mode Examples

Text mode is perhaps the simplest mode besides Fundamental mode. Here are excerpts from `text-mode.el' that illustrate many of the conventions listed above:

 
;; Create mode-specific tables.
(defvar text-mode-syntax-table nil
  "Syntax table used while in text mode.")

(if text-mode-syntax-table
    ()              ; Do not change the table if it is already set up.
  (setq text-mode-syntax-table (make-syntax-table))
  (modify-syntax-entry ?\" ".   " text-mode-syntax-table)
  (modify-syntax-entry ?\\ ".   " text-mode-syntax-table)
  (modify-syntax-entry ?' "w   " text-mode-syntax-table))

(defvar text-mode-abbrev-table nil
  "Abbrev table used while in text mode.")
(define-abbrev-table 'text-mode-abbrev-table ())

(defvar text-mode-map nil)   ; Create a mode-specific keymap.

(if text-mode-map
    ()              ; Do not change the keymap if it is already set up.
  (setq text-mode-map (make-sparse-keymap))
  (define-key text-mode-map "\t" 'tab-to-tab-stop)
  (define-key text-mode-map "\es" 'center-line)
  (define-key text-mode-map "\eS" 'center-paragraph))

Here is the complete major mode function definition for Text mode:

 
(defun text-mode ()
  "Major mode for editing text intended for humans to read.
 Special commands: \\{text-mode-map}
Turning on text-mode runs the hook `text-mode-hook'."
  (interactive)
  (kill-all-local-variables)
  (use-local-map text-mode-map)     ; This provides the local keymap.
  (setq mode-name "Text")           ; This name goes into the modeline.
  (setq major-mode 'text-mode)      ; This is how describe-mode
                                    ;   finds the doc string to print.
  (setq local-abbrev-table text-mode-abbrev-table)
  (set-syntax-table text-mode-syntax-table)
  (run-hooks 'text-mode-hook))      ; Finally, this permits the user to
                                    ;   customize the mode with a hook.

The three Lisp modes (Lisp mode, Emacs Lisp mode, and Lisp Interaction mode) have more features than Text mode and the code is correspondingly more complicated. Here are excerpts from `lisp-mode.el' that illustrate how these modes are written.

 
;; Create mode-specific table variables.
(defvar lisp-mode-syntax-table nil "")
(defvar emacs-lisp-mode-syntax-table nil "")
(defvar lisp-mode-abbrev-table nil "")

(if (not emacs-lisp-mode-syntax-table) ; Do not change the table
                                       ;   if it is already set.
    (let ((i 0))
      (setq emacs-lisp-mode-syntax-table (make-syntax-table))

      ;; Set syntax of chars up to 0 to class of chars that are
      ;;   part of symbol names but not words.
      ;;   (The number 0 is 48 in the ASCII character set.)
      (while (< i ?0)
        (modify-syntax-entry i "_   " emacs-lisp-mode-syntax-table)
        (setq i (1+ i)))
      ...
      ;; Set the syntax for other characters.
      (modify-syntax-entry ?  "    " emacs-lisp-mode-syntax-table)
      (modify-syntax-entry ?\t "    " emacs-lisp-mode-syntax-table)
      ...
      (modify-syntax-entry ?\( "()  " emacs-lisp-mode-syntax-table)
      (modify-syntax-entry ?\) ")(  " emacs-lisp-mode-syntax-table)
      ...))
;; Create an abbrev table for lisp-mode.
(define-abbrev-table 'lisp-mode-abbrev-table ())

Much code is shared among the three Lisp modes. The following function sets various variables; it is called by each of the major Lisp mode functions:

 
(defun lisp-mode-variables (lisp-syntax)
  ;; The lisp-syntax argument is nil in Emacs Lisp mode,
  ;;   and t in the other two Lisp modes.
  (cond (lisp-syntax
         (if (not lisp-mode-syntax-table)
             ;; The Emacs Lisp mode syntax table always exists, but
             ;;   the Lisp Mode syntax table is created the first time a
             ;;   mode that needs it is called.  This is to save space.
             (progn (setq lisp-mode-syntax-table
                       (copy-syntax-table emacs-lisp-mode-syntax-table))
                    ;; Change some entries for Lisp mode.
                    (modify-syntax-entry ?\| "\"   "
                                         lisp-mode-syntax-table)
                    (modify-syntax-entry ?\[ "_   "
                                         lisp-mode-syntax-table)
                    (modify-syntax-entry ?\] "_   "
                                         lisp-mode-syntax-table)))
          (set-syntax-table lisp-mode-syntax-table)))
  (setq local-abbrev-table lisp-mode-abbrev-table)
  ...)

Functions such as forward-paragraph use the value of the paragraph-start variable. Since Lisp code is different from ordinary text, the paragraph-start variable needs to be set specially to handle Lisp. Also, comments are indented in a special fashion in Lisp and the Lisp modes need their own mode-specific comment-indent-function. The code to set these variables is the rest of lisp-mode-variables.

 
  (make-local-variable 'paragraph-start)
  ;; Having `^' is not clean, but page-delimiter
  ;; has them too, and removing those is a pain.
  (setq paragraph-start (concat "^$\\|" page-delimiter))
  ...
  (make-local-variable 'comment-indent-function)
  (setq comment-indent-function 'lisp-comment-indent))

Each of the different Lisp modes has a slightly different keymap. For example, Lisp mode binds C-c C-l to run-lisp, but the other Lisp modes do not. However, all Lisp modes have some commands in common. The following function adds these common commands to a given keymap.

 
(defun lisp-mode-commands (map)
  (define-key map "\e\C-q" 'indent-sexp)
  (define-key map "\177" 'backward-delete-char-untabify)
  (define-key map "\t" 'lisp-indent-line))

Here is an example of using lisp-mode-commands to initialize a keymap, as part of the code for Emacs Lisp mode. First we declare a variable with defvar to hold the mode-specific keymap. When this defvar executes, it sets the variable to nil if it was void. Then we set up the keymap if the variable is nil.

This code avoids changing the keymap or the variable if it is already set up. This lets the user customize the keymap.

 
(defvar emacs-lisp-mode-map () "")
(if emacs-lisp-mode-map
    ()
  (setq emacs-lisp-mode-map (make-sparse-keymap))
  (define-key emacs-lisp-mode-map "\e\C-x" 'eval-defun)
  (lisp-mode-commands emacs-lisp-mode-map))

Finally, here is the complete major mode function definition for Emacs Lisp mode.

 
(defun emacs-lisp-mode ()
  "Major mode for editing Lisp code to run in XEmacs.
Commands:
Delete converts tabs to spaces as it moves back.
Blank lines separate paragraphs.  Semicolons start comments.
\\{emacs-lisp-mode-map}
Entry to this mode runs the hook `emacs-lisp-mode-hook'."
  (interactive)
  (kill-all-local-variables)
  (use-local-map emacs-lisp-mode-map)    ; This provides the local keymap.
  (set-syntax-table emacs-lisp-mode-syntax-table)
  (setq major-mode 'emacs-lisp-mode)     ; This is how describe-mode
                                         ;   finds out what to describe.
  (setq mode-name "Emacs-Lisp")          ; This goes into the modeline.
  (lisp-mode-variables nil)              ; This defines various variables.
  (run-hooks 'emacs-lisp-mode-hook))     ; This permits the user to use a
                                         ;   hook to customize the mode.


[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [Top] [Contents] [Index] [ ? ]

33.1.3 How XEmacs Chooses a Major Mode

Based on information in the file name or in the file itself, XEmacs automatically selects a major mode for the new buffer when a file is visited.

Command: fundamental-mode
Fundamental mode is a major mode that is not specialized for anything in particular. Other major modes are defined in effect by comparison with this one--their definitions say what to change, starting from Fundamental mode. The fundamental-mode function does not run any hooks; you're not supposed to customize it. (If you want Emacs to behave differently in Fundamental mode, change the global state of Emacs.)

Command: normal-mode &optional find-file
This function establishes the proper major mode and local variable bindings for the current buffer. First it calls set-auto-mode, then it runs hack-local-variables to parse, and bind or evaluate as appropriate, any local variables.

If the find-file argument to normal-mode is non-nil, normal-mode assumes that the find-file function is calling it. In this case, it may process a local variables list at the end of the file and in the `-*-' line. The variable enable-local-variables controls whether to do so.

If you run normal-mode interactively, the argument find-file is normally nil. In this case, normal-mode unconditionally processes any local variables list. See section `Local Variables in Files' in The XEmacs Reference Manual, for the syntax of the local variables section of a file.

normal-mode uses condition-case around the call to the major mode function, so errors are caught and reported as a `File mode specification error', followed by the original error message.

User Option: enable-local-variables
This variable controls processing of local variables lists in files being visited. A value of t means process the local variables lists unconditionally; nil means ignore them; anything else means ask the user what to do for each file. The default value is t.

Variable: ignored-local-variables
This variable holds a list of variables that should not be set by a local variables list. Any value specified for one of these variables is ignored.

In addition to this list, any variable whose name has a non-nil risky-local-variable property is also ignored.

User Option: enable-local-eval
This variable controls processing of `Eval:' in local variables lists in files being visited. A value of t means process them unconditionally; nil means ignore them; anything else means ask the user what to do for each file. The default value is maybe.

Function: set-auto-mode
This function selects the major mode that is appropriate for the current buffer. It may base its decision on the value of the `-*-' line, on the visited file name (using auto-mode-alist), or on the value of a local variable. However, this function does not look for the `mode:' local variable near the end of a file; the hack-local-variables function does that. See section `How Major Modes are Chosen' in The XEmacs Lisp Reference Manual.

User Option: default-major-mode
This variable holds the default major mode for new buffers. The standard value is fundamental-mode.

If the value of default-major-mode is nil, XEmacs uses the (previously) current buffer's major mode for the major mode of a new buffer. However, if the major mode symbol has a mode-class property with value special, then it is not used for new buffers; Fundamental mode is used instead. The modes that have this property are those such as Dired and Rmail that are useful only with text that has been specially prepared.

Function: set-buffer-major-mode buffer
This function sets the major mode of buffer to the value of default-major-mode. If that variable is nil, it uses the current buffer's major mode (if that is suitable).

The low-level primitives for creating buffers do not use this function, but medium-level commands such as switch-to-buffer and find-file-noselect use it whenever they create buffers.

Variable: initial-major-mode
The value of this variable determines the major mode of the initial `*scratch*' buffer. The value should be a symbol that is a major mode command name. The default value is lisp-interaction-mode.

Variable: auto-mode-alist
This variable contains an association list of file name patterns (regular expressions; see section 44.2 Regular Expressions) and corresponding major mode functions. Usually, the file name patterns test for suffixes, such as `.el' and `.c', but this need not be the case. An ordinary element of the alist looks like (regexp . mode-function).

For example,

 
(("^/tmp/fol/" . text-mode)
 ("\\.texinfo\\'" . texinfo-mode)
 ("\\.texi\\'" . texinfo-mode)
 ("\\.el\\'" . emacs-lisp-mode)
 ("\\.c\\'" . c-mode)
 ("\\.h\\'" . c-mode)
 ...)

When you visit a file whose expanded file name (see section 35.8.4 Functions that Expand Filenames) matches a regexp, set-auto-mode calls the corresponding mode-function. This feature enables XEmacs to select the proper major mode for most files.

If an element of auto-mode-alist has the form (regexp function t), then after calling function, XEmacs searches auto-mode-alist again for a match against the portion of the file name that did not match before.

This match-again feature is useful for uncompression packages: an entry of the form ("\\.gz\\'" . function) can uncompress the file and then put the uncompressed file in the proper mode according to the name sans `.gz'.

Here is an example of how to prepend several pattern pairs to auto-mode-alist. (You might use this sort of expression in your `.emacs' file.)

 
(setq auto-mode-alist
  (append
   ;; File name starts with a dot.
   '(("/\\.[^/]*\\'" . fundamental-mode)
     ;; File name has no dot.
     ("[^\\./]*\\'" . fundamental-mode)
     ;; File name ends in `.C'.
     ("\\.C\\'" . c++-mode))
   auto-mode-alist))

Variable: interpreter-mode-alist
This variable specifies major modes to use for scripts that specify a command interpreter in an `#!' line. Its value is a list of elements of the form (interpreter . mode); for example, ("perl" . perl-mode) is one element present by default. The element says to use mode mode if the file specifies interpreter.

This variable is applicable only when the auto-mode-alist does not indicate which major mode to use.

Function: hack-local-variables &optional force
This function parses, and binds or evaluates as appropriate, any local variables for the current buffer.

The handling of enable-local-variables documented for normal-mode actually takes place here. The argument force usually comes from the argument find-file given to normal-mode.


[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [Top] [Contents] [Index] [ ? ]

33.1.4 Getting Help about a Major Mode

The describe-mode function is used to provide information about major modes. It is normally called with C-h m. The describe-mode function uses the value of major-mode, which is why every major mode function needs to set the major-mode variable.

Command: describe-mode
This function displays the documentation of the current major mode.

The describe-mode function calls the documentation function using the value of major-mode as an argument. Thus, it displays the documentation string of the major mode function. (See section 34.2 Access to Documentation Strings.)

Variable: major-mode
This variable holds the symbol for the current buffer's major mode. This symbol should have a function definition that is the command to switch to that major mode. The describe-mode function uses the documentation string of the function as the documentation of the major mode.


[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [Top] [Contents] [Index] [ ? ]

33.1.5 Defining Derived Modes

It's often useful to define a new major mode in terms of an existing one. An easy way to do this is to use define-derived-mode.

Macro: define-derived-mode variant parent name docstring body...
This construct defines variant as a major mode command, using name as the string form of the mode name.

The new command variant is defined to call the function parent, then override certain aspects of that parent mode:

In addition, you can specify how to override other aspects of parent with body. The command variant evaluates the forms in body after setting up all its usual overrides, just before running variant-hook.

The argument docstring specifies the documentation string for the new mode. If you omit docstring, define-derived-mode generates a documentation string.

Here is a hypothetical example:

 
(define-derived-mode hypertext-mode
  text-mode "Hypertext"
  "Major mode for hypertext.
\\{hypertext-mode-map}"
  (setq case-fold-search nil))

(define-key hypertext-mode-map
  [down-mouse-3] 'do-hyper-link)

Do not write an interactive spec in the definition; define-derived-mode does that automatically.


[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [Top] [Contents] [Index] [ ? ]

33.2 Minor Modes

A minor mode provides features that users may enable or disable independently of the choice of major mode. Minor modes can be enabled individually or in combination. Minor modes would be better named "Generally available, optional feature modes" except that such a name is unwieldy.

A minor mode is not usually a modification of single major mode. For example, Auto Fill mode may be used in any major mode that permits text insertion. To be general, a minor mode must be effectively independent of the things major modes do.

A minor mode is often much more difficult to implement than a major mode. One reason is that you should be able to activate and deactivate minor modes in any order. A minor mode should be able to have its desired effect regardless of the major mode and regardless of the other minor modes in effect.

Often the biggest problem in implementing a minor mode is finding a way to insert the necessary hook into the rest of XEmacs. Minor mode keymaps make this easier than it used to be.

33.2.1 Conventions for Writing Minor Modes  Tips for writing a minor mode.
33.2.2 Keymaps and Minor Modes  How a minor mode can have its own keymap.


[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [Top] [Contents] [Index] [ ? ]

33.2.1 Conventions for Writing Minor Modes

There are conventions for writing minor modes just as there are for major modes. Several of the major mode conventions apply to minor modes as well: those regarding the name of the mode initialization function, the names of global symbols, and the use of keymaps and other tables.

In addition, there are several conventions that are specific to minor modes.


[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [Top] [Contents] [Index] [ ? ]

33.2.2 Keymaps and Minor Modes

Each minor mode can have its own keymap, which is active when the mode is enabled. To set up a keymap for a minor mode, add an element to the alist minor-mode-map-alist. See section 26.7 Active Keymaps.

One use of minor mode keymaps is to modify the behavior of certain self-inserting characters so that they do something else as well as self-insert. In general, this is the only way to do that, since the facilities for customizing self-insert-command are limited to special cases (designed for abbrevs and Auto Fill mode). (Do not try substituting your own definition of self-insert-command for the standard one. The editor command loop handles this function specially.)


[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [Top] [Contents] [Index] [ ? ]

33.3 Modeline Format

Each Emacs window (aside from minibuffer windows) includes a modeline, which displays status information about the buffer displayed in the window. The modeline contains information about the buffer, such as its name, associated file, depth of recursive editing, and the major and minor modes.

This section describes how the contents of the modeline are controlled. It is in the chapter on modes because much of the information displayed in the modeline relates to the enabled major and minor modes.

modeline-format is a buffer-local variable that holds a template used to display the modeline of the current buffer. All windows for the same buffer use the same modeline-format and their modelines appear the same (except for scrolling percentages and line numbers).

The modeline of a window is normally updated whenever a different buffer is shown in the window, or when the buffer's modified-status changes from nil to t or vice-versa. If you modify any of the variables referenced by modeline-format (see section 33.3.2 Variables Used in the Modeline), you may want to force an update of the modeline so as to display the new information.

Function: redraw-modeline &optional all
Force redisplay of the current buffer's modeline. If all is non-nil, then force redisplay of all modelines.

The modeline is usually displayed in inverse video. This is controlled using the modeline face. See section 49.1 Faces.

33.3.1 The Data Structure of the Modeline  The data structure that controls the modeline.
33.3.2 Variables Used in the Modeline  Variables used in that data structure.
33.3.3 %-Constructs in the ModeLine  Putting information into a modeline.


[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [Top] [Contents] [Index] [ ? ]

33.3.1 The Data Structure of the Modeline

The modeline contents are controlled by a data structure of lists, strings, symbols, and numbers kept in the buffer-local variable modeline-format. The data structure is called a modeline construct, and it is built in recursive fashion out of simpler modeline constructs. The same data structure is used for constructing frame titles (see section 39.3 Frame Titles).

Variable: modeline-format
The value of this variable is a modeline construct with overall responsibility for the modeline format. The value of this variable controls which other variables are used to form the modeline text, and where they appear.

A modeline construct may be as simple as a fixed string of text, but it usually specifies how to use other variables to construct the text. Many of these variables are themselves defined to have modeline constructs as their values.

The default value of modeline-format incorporates the values of variables such as mode-name and minor-mode-alist. Because of this, very few modes need to alter modeline-format. For most purposes, it is sufficient to alter the variables referenced by modeline-format.

A modeline construct may be a string, symbol, glyph, generic specifier, list or cons cell.

string
A string as a modeline construct is displayed verbatim in the mode line except for %-constructs. Decimal digits after the `%' specify the field width for space filling on the right (i.e., the data is left justified). See section 33.3.3 %-Constructs in the ModeLine.

symbol
A symbol as a modeline construct stands for its value. The value of symbol is processed as a modeline construct, in place of symbol. However, the symbols t and nil are ignored; so is any symbol whose value is void.

There is one exception: if the value of symbol is a string, it is displayed verbatim: the %-constructs are not recognized.

glyph
A glyph is displayed as is.

generic-specifier
A generic-specifier (i.e. a specifier of type generic) stands for its instance. The instance of generic-specifier is computed in the current window using the equivalent of specifier-instance and the value is processed.

(string rest...) or (list rest...)
A list whose first element is a string or list means to process all the elements recursively and concatenate the results. This is the most common form of mode line construct.

(symbol then else)
A list whose first element is a symbol is a conditional. Its meaning depends on the value of symbol. If the value is non-nil, the second element, then, is processed recursively as a modeline element. But if the value of symbol is nil, the third element, else, is processed recursively. You may omit else; then the mode line element displays nothing if the value of symbol is nil.

(width rest...)
A list whose first element is an integer specifies truncation or padding of the results of rest. The remaining elements rest are processed recursively as modeline constructs and concatenated together. Then the result is space filled (if width is positive) or truncated (to -width columns, if width is negative) on the right.

For example, the usual way to show what percentage of a buffer is above the top of the window is to use a list like this: (-3 "%p").

(extent rest...)

A list whose car is an extent means the cdr of the list is processed normally but the results are displayed using the face of the extent, and mouse clicks over this section are processed using the keymap of the extent. (In addition, if the extent has a help-echo property, that string will be echoed when the mouse moves over this section.) If extents are nested, all keymaps are properly consulted when processing mouse clicks, but multiple faces are not correctly merged (only the first face is used), and lists of faces are not correctly handled.

If you do alter modeline-format itself, the new value should use the same variables that appear in the default value (see section 33.3.2 Variables Used in the Modeline), rather than duplicating their contents or displaying the information in another fashion. This way, customizations made by the user or by Lisp programs (such as display-time and major modes) via changes to those variables remain effective.

Here is an example of a modeline-format that might be useful for shell-mode, since it contains the hostname and default directory.

 
(setq modeline-format
  (list ""
   'modeline-modified
   "%b--"
   (getenv "HOST")      ; One element is not constant.
   ":"
   'default-directory
   "   "
   'global-mode-string
   "   %[("
   'mode-name
   'modeline-process
   'minor-mode-alist
   "%n"
   ")%]----"
   '(line-number-mode "L%l--")
   '(-3 . "%p")
   "-%-"))


[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [Top] [Contents] [Index] [ ? ]

33.3.2 Variables Used in the Modeline

This section describes variables incorporated by the standard value of modeline-format into the text of the mode line. There is nothing inherently special about these variables; any other variables could have the same effects on the modeline if modeline-format were changed to use them.

Variable: modeline-modified
This variable holds the value of the modeline construct that displays whether the current buffer is modified.

The default value of modeline-modified is ("--%1*%1+-"). This means that the modeline displays `--**-' if the buffer is modified, `-----' if the buffer is not modified, `--%%-' if the buffer is read only, and `--%*--' if the buffer is read only and modified.

Changing this variable does not force an update of the modeline.

Variable: modeline-buffer-identification
This variable identifies the buffer being displayed in the window. Its default value is ("%F: %17b"), which means that it usually displays `Emacs:' followed by seventeen characters of the buffer name. (In a terminal frame, it displays the frame name instead of `Emacs'; this has the effect of showing the frame number.) You may want to change this in modes such as Rmail that do not behave like a "normal" XEmacs.

Variable: global-mode-string
This variable holds a modeline spec that appears in the mode line by default, just after the buffer name. The command display-time sets global-mode-string to refer to the variable display-time-string, which holds a string containing the time and load information.

The `%M' construct substitutes the value of global-mode-string, but this is obsolete, since the variable is included directly in the modeline.

Variable: mode-name
This buffer-local variable holds the "pretty" name of the current buffer's major mode. Each major mode should set this variable so that the mode name will appear in the modeline.

Variable: minor-mode-alist
This variable holds an association list whose elements specify how the modeline should indicate that a minor mode is active. Each element of the minor-mode-alist should be a two-element list:

 
(minor-mode-variable modeline-string)

More generally, modeline-string can be any mode line spec. It appears in the mode line when the value of minor-mode-variable is non-nil, and not otherwise. These strings should begin with spaces so that they don't run together. Conventionally, the minor-mode-variable for a specific mode is set to a non-nil value when that minor mode is activated.

The default value of minor-mode-alist is:

 
minor-mode-alist
=> ((vc-mode vc-mode)
    (abbrev-mode " Abbrev")
    (overwrite-mode overwrite-mode)
    (auto-fill-function " Fill")
    (defining-kbd-macro " Def")
    (isearch-mode isearch-mode))

minor-mode-alist is not buffer-local. The variables mentioned in the alist should be buffer-local if the minor mode can be enabled separately in each buffer.

Variable: modeline-process
This buffer-local variable contains the modeline information on process status in modes used for communicating with subprocesses. It is displayed immediately following the major mode name, with no intervening space. For example, its value in the `*shell*' buffer is (": %s"), which allows the shell to display its status along with the major mode as: `(Shell: run)'. Normally this variable is nil.

Variable: default-modeline-format
This variable holds the default modeline-format for buffers that do not override it. This is the same as (default-value 'modeline-format).

The default value of default-modeline-format is:

 
(""
 modeline-modified
 modeline-buffer-identification
 "   "
 global-mode-string
 "   %[("
 mode-name
 modeline-process
 minor-mode-alist
 "%n"
 ")%]----"
 (line-number-mode "L%l--")
 (-3 . "%p")
 "-%-")

Variable: vc-mode
The variable vc-mode, local in each buffer, records whether the buffer's visited file is maintained with version control, and, if so, which kind. Its value is nil for no version control, or a string that appears in the mode line.


[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [Top] [Contents] [Index] [ ? ]

33.3.3 %-Constructs in the ModeLine

The following table lists the recognized %-constructs and what they mean. In any construct except `%%', you can add a decimal integer after the `%' to specify how many characters to display.

%b
The current buffer name, obtained with the buffer-name function. See section 37.3 Buffer Names.

%f
The visited file name, obtained with the buffer-file-name function. See section 37.4 Buffer File Name.

%F
The name of the selected frame.

%c
The current column number of point.

%l
The current line number of point.

%*
`%' if the buffer is read only (see buffer-read-only);
`*' if the buffer is modified (see buffer-modified-p);
`-' otherwise. See section 37.5 Buffer Modification.

%+
`*' if the buffer is modified (see buffer-modified-p);
`%' if the buffer is read only (see buffer-read-only);
`-' otherwise. This differs from `%*' only for a modified read-only buffer. See section 37.5 Buffer Modification.

%&
`*' if the buffer is modified, and `-' otherwise.

%s
The status of the subprocess belonging to the current buffer, obtained with process-status. See section 56.6 Process Information.

%l
The current line number.

%S
The name of the selected frame; this is only meaningful under the X Window System. See section 39.2.5 The Name of a Frame (As Opposed to Its Title).

%t
Whether the visited file is a text file or a binary file. (This is a meaningful distinction only on certain operating systems.)

%p
The percentage of the buffer text above the top of window, or `Top', `Bottom' or `All'.

%P
The percentage of the buffer text that is above the bottom of the window (which includes the text visible in the window, as well as the text above the top), plus `Top' if the top of the buffer is visible on screen; or `Bottom' or `All'.

%n
`Narrow' when narrowing is in effect; nothing otherwise (see narrow-to-region in 41.4 Narrowing).

%C
Under XEmacs/mule, the mnemonic for buffer-file-coding-system.

%[
An indication of the depth of recursive editing levels (not counting minibuffer levels): one `[' for each editing level. See section 25.10 Recursive Editing.

%]
One `]' for each recursive editing level (not counting minibuffer levels).

%%
The character `%'---this is how to include a literal `%' in a string in which %-constructs are allowed.

%-
Dashes sufficient to fill the remainder of the modeline.

The following two %-constructs are still supported, but they are obsolete, since you can get the same results with the variables mode-name and global-mode-string.

%m
The value of mode-name.

%M
The value of global-mode-string. Currently, only display-time modifies the value of global-mode-string.


[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [Top] [Contents] [Index] [ ? ]

33.4 Hooks

A hook is a variable where you can store a function or functions to be called on a particular occasion by an existing program. XEmacs provides hooks for the sake of customization. Most often, hooks are set up in the `.emacs' file, but Lisp programs can set them also. See section F. Standard Hooks, for a list of standard hook variables.

Most of the hooks in XEmacs are normal hooks. These variables contain lists of functions to be called with no arguments. The reason most hooks are normal hooks is so that you can use them in a uniform way. You can usually tell when a hook is a normal hook, because its name ends in `-hook'.

The recommended way to add a hook function to a normal hook is by calling add-hook (see below). The hook functions may be any of the valid kinds of functions that funcall accepts (see section 17.1 What Is a Function?). Most normal hook variables are initially void; add-hook knows how to deal with this.

As for abnormal hooks, those whose names end in `-function' have a value that is a single function. Those whose names end in `-hooks' have a value that is a list of functions. Any hook that is abnormal is abnormal because a normal hook won't do the job; either the functions are called with arguments, or their values are meaningful. The name shows you that the hook is abnormal and that you should look at its documentation string to see how to use it properly.

Major mode functions are supposed to run a hook called the mode hook as the last step of initialization. This makes it easy for a user to customize the behavior of the mode, by overriding the local variable assignments already made by the mode. But hooks are used in other contexts too. For example, the hook suspend-hook runs just before XEmacs suspends itself (see section 57.2.2 Suspending XEmacs).

Here's an expression that uses a mode hook to turn on Auto Fill mode when in Lisp Interaction mode:

 
(add-hook 'lisp-interaction-mode-hook 'turn-on-auto-fill)

The next example shows how to use a hook to customize the way XEmacs formats C code. (People often have strong personal preferences for one format or another.) Here the hook function is an anonymous lambda expression.

 
(add-hook 'c-mode-hook
  (function (lambda ()
              (setq c-indent-level 4
                    c-argdecl-indent 0
                    c-label-offset -4
                    c-continued-statement-indent 0
                    c-brace-offset 0
                    comment-column 40))))

(setq c++-mode-hook c-mode-hook)

The final example shows how the appearance of the modeline can be modified for a particular class of buffers only.

 
(add-hook 'text-mode-hook
  (function (lambda ()
              (setq modeline-format
                    '(modeline-modified
                      "Emacs: %14b"
                      "  "
                      default-directory
                      " "
                      global-mode-string
                      "%[("
                      mode-name
                      minor-mode-alist
                      "%n"
                      modeline-process
                      ") %]---"
                      (-3 . "%p")
                      "-%-")))))

At the appropriate time, XEmacs uses the run-hooks function to run particular hooks. This function calls the hook functions you have added with add-hooks.

Function: run-hooks &rest hookvar
This function takes one or more hook variable names as arguments, and runs each hook in turn. Each hookvar argument should be a symbol that is a hook variable. These arguments are processed in the order specified.

If a hook variable has a non-nil value, that value may be a function or a list of functions. If the value is a function (either a lambda expression or a symbol with a function definition), it is called. If it is a list, the elements are called, in order. The hook functions are called with no arguments.

For example, here's how emacs-lisp-mode runs its mode hook:

 
(run-hooks 'emacs-lisp-mode-hook)

Function: run-mode-hooks &rest hookvars
Like run-hooks, but is affected by the delay-mode-hooks macro.

Macro: delay-mode-hooks body...
This macro executes the body forms but defers all calls to run-mode-hooks within them until the end of body. This macro enables a derived mode to arrange not to run its parent modes' mode hooks until the end.

Function: run-hook-with-args hook &rest args
This function is the way to run an abnormal hook and always call all of the hook functions. It calls each of the hook functions one by one, passing each of them the arguments args.

Function: run-hook-with-args-until-failure hook &rest args
This function is the way to run an abnormal hook until one of the hook functions fails. It calls each of the hook functions, passing each of them the arguments args, until some hook function returns nil. It then stops and returns nil. If none of the hook functions return nil, it returns a non-nil value.

Function: run-hook-with-args-until-success hook &rest args
This function is the way to run an abnormal hook until a hook function succeeds. It calls each of the hook functions, passing each of them the arguments args, until some hook function returns non-nil. Then it stops, and returns whatever was returned by the last hook function that was called. If all hook functions return nil, it returns nil as well.

Function: add-hook hook function &optional append local
This function is the handy way to add function function to hook variable hook. The argument function may be any valid Lisp function with the proper number of arguments. For example,

 
(add-hook 'text-mode-hook 'my-text-hook-function)

adds my-text-hook-function to the hook called text-mode-hook.

You can use add-hook for abnormal hooks as well as for normal hooks.

It is best to design your hook functions so that the order in which they are executed does not matter. Any dependence on the order is "asking for trouble." However, the order is predictable: normally, function goes at the front of the hook list, so it will be executed first (barring another add-hook call).

If the optional argument append is non-nil, the new hook function goes at the end of the hook list and will be executed last.

If local is non-nil, that says to make the new hook function local to the current buffer. Before you can do this, you must make the hook itself buffer-local by calling make-local-hook (not make-local-variable). If the hook itself is not buffer-local, then the value of local makes no difference--the hook function is always global.

Function: remove-hook hook function &optional local
This function removes function from the hook variable hook.

If local is non-nil, that says to remove function from the local hook list instead of from the global hook list. If the hook itself is not buffer-local, then the value of local makes no difference.

Function: make-local-hook hook
This function makes the hook variable hook local to the current buffer. When a hook variable is local, it can have local and global hook functions, and run-hooks runs all of them.

This function works by making t an element of the buffer-local value. That serves as a flag to use the hook functions in the default value of the hook variable as well as those in the local value. Since run-hooks understands this flag, make-local-hook works with all normal hooks. It works for only some non-normal hooks--those whose callers have been updated to understand this meaning of t.

Do not use make-local-variable directly for hook variables; it is not sufficient.


[ << ] [ >> ]           [Top] [Contents] [Index] [ ? ]

This document was generated by XEmacs Webmaster on August, 3 2012 using texi2html