[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [Top] [Contents] [Index] [ ? ]

38. Windows

This chapter describes most of the functions and variables related to Emacs windows. See 52. Emacs Display, for information on how text is displayed in windows.

38.1 Basic Concepts of Emacs Windows  Basic information on using windows.
38.2 Splitting Windows  Splitting one window into two windows.
38.3 Deleting Windows  Deleting a window gives its space to other windows.
38.4 Selecting Windows  The selected window is the one that you edit in.
38.5 Cyclic Ordering of Windows  Moving around the existing windows.
38.6 Buffers and Windows  Each window displays the contents of a buffer.
38.7 Displaying Buffers in Windows  Higher-lever functions for displaying a buffer and choosing a window for it.
38.8 Choosing a Window for Display  How to choose a window for displaying a buffer.
38.9 Windows and Point  Each window has its own location of point.
38.10 The Window Start Position  The display-start position controls which text is on-screen in the window.
38.11 Vertical Scrolling  Moving text up and down in the window.
38.12 Horizontal Scrolling  Moving text sideways on the window.
38.13 The Size of a Window  Accessing the size of a window.
38.14 The Position of a Window  Accessing the position of a window.
38.15 Changing the Size of a Window  Changing the size of a window.
38.16 Window Configurations  Saving and restoring the state of the screen.


[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [Top] [Contents] [Index] [ ? ]

38.1 Basic Concepts of Emacs Windows

A window in XEmacs is the physical area of the screen in which a buffer is displayed. The term is also used to refer to a Lisp object that represents that screen area in XEmacs Lisp. It should be clear from the context which is meant.

XEmacs groups windows into frames. A frame represents an area of screen available for XEmacs to use. Each frame always contains at least one window, but you can subdivide it vertically or horizontally into multiple nonoverlapping Emacs windows.

In each frame, at any time, one and only one window is designated as selected within the frame. The frame's cursor appears in that window. At any time, one frame is the selected frame; and the window selected within that frame is the selected window. The selected window's buffer is usually the current buffer (except when set-buffer has been used). See section 37.2 The Current Buffer.

For practical purposes, a window exists only while it is displayed in a frame. Once removed from the frame, the window is effectively deleted and should not be used, even though there may still be references to it from other Lisp objects. Restoring a saved window configuration is the only way for a window no longer on the screen to come back to life. (See section 38.3 Deleting Windows.)

Each window has the following attributes:

Users create multiple windows so they can look at several buffers at once. Lisp libraries use multiple windows for a variety of reasons, but most often to display related information. In Rmail, for example, you can move through a summary buffer in one window while the other window shows messages one at a time as they are reached.

The meaning of "window" in XEmacs is similar to what it means in the context of general-purpose window systems such as X, but not identical. The X Window System places X windows on the screen; XEmacs uses one or more X windows as frames, and subdivides them into Emacs windows. When you use XEmacs on a character-only terminal, XEmacs treats the whole terminal screen as one frame.

Most window systems support arbitrarily located overlapping windows. In contrast, Emacs windows are tiled; they never overlap, and together they fill the whole screen or frame. Because of the way in which XEmacs creates new windows and resizes them, you can't create every conceivable tiling of windows on an Emacs frame. See section 38.2 Splitting Windows, and 38.13 The Size of a Window.

See section 52. Emacs Display, for information on how the contents of the window's buffer are displayed in the window.

Function: windowp object
This function returns t if object is a window.


[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [Top] [Contents] [Index] [ ? ]

38.2 Splitting Windows

The functions described here are the primitives used to split a window into two windows. Two higher level functions sometimes split a window, but not always: pop-to-buffer and display-buffer (see section 38.7 Displaying Buffers in Windows).

The functions described here do not accept a buffer as an argument. The two "halves" of the split window initially display the same buffer previously visible in the window that was split.

Function: one-window-p &optional nomini which-frames which-devices
This function returns non-nil if there is only one window. The argument nomini, if non-nil, means don't count the minibuffer even if it is active; otherwise, the minibuffer window is included, if active, in the total number of windows which is compared against one.

The remaining arguments controls which set of windows are counted, as with next-window.

Command: split-window &optional window size horizontal
This function splits window into two windows. The original window window remains the selected window, but occupies only part of its former screen area. The rest is occupied by a newly created window which is returned as the value of this function.

If horizontal is non-nil, then window splits into two side by side windows. The original window window keeps the leftmost size columns, and gives the rest of the columns to the new window. Otherwise, it splits into windows one above the other, and window keeps the upper size lines and gives the rest of the lines to the new window. The original window is therefore the left-hand or upper of the two, and the new window is the right-hand or lower.

If window is omitted or nil, then the selected window is split. If size is omitted or nil, then window is divided evenly into two parts. (If there is an odd line, it is allocated to the new window.) When split-window is called interactively, all its arguments are nil.

The following example starts with one window on a frame that is 50 lines high by 80 columns wide; then the window is split.

 
(setq w (selected-window))
     => #<window 8 on windows.texi>
(window-edges)          ; Edges in order:
     => (0 0 80 50)     ;   left--top--right--bottom

;; Returns window created
(setq w2 (split-window w 15))
     => #<window 28 on windows.texi>
(window-edges w2)
     => (0 15 80 50)    ; Bottom window;
                        ;   top is line 15
(window-edges w)
     => (0 0 80 15)     ; Top window

The frame looks like this:

 
         __________
        |          |  line 0
        |    w     |
        |__________|
        |          |  line 15
        |    w2    |
        |__________|
                      line 50
 column 0   column 80

Next, the top window is split horizontally:

 
(setq w3 (split-window w 35 t))
     => #<window 32 on windows.texi>
(window-edges w3)
     => (35 0 80 15)  ; Left edge at column 35
(window-edges w)
     => (0 0 35 15)   ; Right edge at column 35
(window-edges w2)
     => (0 15 80 50)  ; Bottom window unchanged

Now, the screen looks like this:

 
     column 35
         __________
        |   |      |  line 0
        | w |  w3  |
        |___|______|
        |          |  line 15
        |    w2    |
        |__________|
                      line 50
 column 0   column 80

Normally, Emacs indicates the border between two side-by-side windows with a scroll bar (see section Scroll Bars) or `|' characters. The display table can specify alternative border characters; see 52.11 Display Tables.

Command: split-window-vertically &optional size
This function splits the selected window into two windows, one above the other, leaving the selected window with size lines.

This function is simply an interface to split-window. Here is the complete function definition for it:

 
(defun split-window-vertically (&optional arg)
  "Split current window into two windows, one above the other."
  (interactive "P")
  (split-window nil (and arg (prefix-numeric-value arg))))

Command: split-window-horizontally &optional size
This function splits the selected window into two windows side-by-side, leaving the selected window with size columns.

This function is simply an interface to split-window. Here is the complete definition for split-window-horizontally (except for part of the documentation string):

 
(defun split-window-horizontally (&optional arg)
  "Split selected window into two windows, side by side..."
  (interactive "P")
  (split-window nil (and arg (prefix-numeric-value arg)) t))


[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [Top] [Contents] [Index] [ ? ]

38.3 Deleting Windows

A window remains visible on its frame unless you delete it by calling certain functions that delete windows. A deleted window cannot appear on the screen, but continues to exist as a Lisp object until there are no references to it. There is no way to cancel the deletion of a window aside from restoring a saved window configuration (see section 38.16 Window Configurations). Restoring a window configuration also deletes any windows that aren't part of that configuration.

When you delete a window, the space it took up is given to one adjacent sibling. (In Emacs version 18, the space was divided evenly among all the siblings.)

Function: window-live-p window
This function returns nil if window is deleted, and t otherwise.

Warning: Erroneous information or fatal errors may result from using a deleted window as if it were live.

Command: delete-window &optional window force
This function removes window from the display. If window is omitted, then the selected window is deleted. If window is the only one on its frame, the frame is deleted as well.

Normally, you cannot delete the last non-minibuffer-only frame (you must use save-buffers-kill-emacs or kill-emacs); an error is signaled instead. However, if optional second argument force is non-nil, you can delete the last frame. (This will automatically call save-buffers-kill-emacs.)

This function returns nil.

When delete-window is called interactively, the selected window is deleted.

Command: delete-other-windows &optional window
This function makes window the only window on its frame, by deleting the other windows in that frame. If window is omitted or nil, then the selected window is used by default.

The result is nil.

Command: delete-windows-on buffer &optional which-frames which-devices
This function deletes all windows showing buffer. If there are no windows showing buffer, it does nothing.

delete-windows-on operates frame by frame. If a frame has several windows showing different buffers, then those showing buffer are removed, and the others expand to fill the space. If all windows in some frame are showing buffer (including the case where there is only one window), then the frame reverts to having a single window showing another buffer chosen with other-buffer. See section 37.8 The Buffer List.

The argument which-frames controls which frames to operate on:

nil
Delete all windows showing buffer in any frame.

t
Delete only windows showing buffer in the selected frame.

visible
Delete all windows showing buffer in any visible frame.

0
Delete all windows showing buffer in any visible frame.

frame
If it is a frame, delete all windows showing buffer in that frame.

Warning: This is similar to, but not identical to, the meaning of the which-frames argument to next-window; the meanings of nil and t are reversed.

The optional argument which-devices further clarifies on which devices to search for frames as specified by which-frames. This value is only meaningful if which-frames is not t.

nil
Consider all devices on the selected console.

device
Consider only the one device device.

console
Consider all devices on console.

device-type
Consider all devices with device type device-type.

window-system
Consider all devices on window system consoles.

anything else
Consider all devices without restriction.

This function always returns nil.


[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [Top] [Contents] [Index] [ ? ]

38.4 Selecting Windows

When a window is selected, the buffer in the window becomes the current buffer, and the cursor will appear in it.

Function: selected-window &optional device
This function returns the selected window. This is the window in which the cursor appears and to which many commands apply. Each separate device can have its own selected window, which is remembered as focus changes from device to device. Optional argument device specifies which device to return the selected window for, and defaults to the selected device.

Function: select-window window &optional norecord
This function makes window the selected window. The cursor then appears in window (on redisplay). The buffer being displayed in window is immediately designated the current buffer.

If optional argument norecord is non-nil then the global and per-frame buffer orderings are not modified, as by the function record-buffer.

The return value is window.

 
(setq w (next-window))
(select-window w)
     => #<window 65 on windows.texi>

Macro: save-selected-window forms...
This macro records the selected window, executes forms in sequence, then restores the earlier selected window. It does not save or restore anything about the sizes, arrangement or contents of windows; therefore, if the forms change them, the changes are permanent.

The following functions choose one of the windows on the screen, offering various criteria for the choice.

Function: get-lru-window &optional which-frames which-devices
This function returns the window least recently "used" (that is, selected). The selected window is always the most recently used window.

The selected window can be the least recently used window if it is the only window. A newly created window becomes the least recently used window until it is selected. A minibuffer window is never a candidate.

By default, only the windows in the selected frame are considered. The optional argument which-frames changes this behavior. Here are the possible values and their meanings:

nil
Consider all the windows in the selected windows's frame, plus the minibuffer used by that frame even if it lies in some other frame.

t
Consider all windows in all existing frames.

visible
Consider all windows in all visible frames. (To get useful results, you must ensure window is in a visible frame.)

0
Consider all windows in all visible or iconified frames.

frame
Consider all windows on frame frame.

anything else
Consider precisely the windows in the selected window's frame, and no others.

The optional argument which-devices further clarifies on which devices to search for frames as specified by which-frames. This value is only meaningful if which-frames is non-nil.

nil
Consider all devices on the selected console.

device
Consider only the one device device.

console
Consider all devices on console.

device-type
Consider all devices with device type device-type.

window-system
Consider all devices on window system consoles.

anything else
Consider all devices without restriction.

Function: get-largest-window &optional which-frames which-devices
This function returns the window with the largest area (height times width). If there are no side-by-side windows, then this is the window with the most lines. A minibuffer window is never a candidate.

If there are two windows of the same size, then the function returns the window that is first in the cyclic ordering of windows (see following section), starting from the selected window.

The remaining arguments control which set of windows are considered. See next-window, above.


[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [Top] [Contents] [Index] [ ? ]

38.5 Cyclic Ordering of Windows

When you use the command C-x o (other-window) to select the next window, it moves through all the windows on the screen in a specific cyclic order. For any given configuration of windows, this order never varies. It is called the cyclic ordering of windows.

This ordering generally goes from top to bottom, and from left to right. But it may go down first or go right first, depending on the order in which the windows were split.

If the first split was vertical (into windows one above each other), and then the subwindows were split horizontally, then the ordering is left to right in the top of the frame, and then left to right in the next lower part of the frame, and so on. If the first split was horizontal, the ordering is top to bottom in the left part, and so on. In general, within each set of siblings at any level in the window tree, the order is left to right, or top to bottom.

Function: next-window &optional window minibuf which-frames which-devices
This function returns the window following window in the cyclic ordering of windows. This is the window that C-x o would select if typed when window is selected. If window is the only window visible, then this function returns window. If omitted, window defaults to the selected window.

The value of the argument minibuf determines whether the minibuffer is included in the window order. Normally, when minibuf is nil, the minibuffer is included if it is currently active; this is the behavior of C-x o. (The minibuffer window is active while the minibuffer is in use. See section 24. Minibuffers.)

If minibuf is t, then the cyclic ordering includes the minibuffer window even if it is not active.

If minibuf is neither t nor nil, then the minibuffer window is not included even if it is active.

By default, only the windows in the selected frame are considered. The optional argument which-frames changes this behavior. Here are the possible values and their meanings:

nil
Consider all the windows in window's frame, plus the minibuffer used by that frame even if it lies in some other frame.

t
Consider all windows in all existing frames.

visible
Consider all windows in all visible frames. (To get useful results, you must ensure window is in a visible frame.)

0
Consider all windows in all visible or iconified frames.

frame
Consider all windows on frame frame.

anything else
Consider precisely the windows in window's frame, and no others.

The optional argument which-devices further clarifies on which devices to search for frames as specified by which-frames. This value is only meaningful if which-frames is non-nil.

nil
Consider all devices on the selected console.

device
Consider only the one device device.

console
Consider all devices on console.

device-type
Consider all devices with device type device-type.

window-system
Consider all devices on window system consoles.

anything else
Consider all devices without restriction.

If you use consistent values for minibuf, which-frames, and which-devices, you can use next-window to iterate through the entire cycle of acceptable windows, eventually ending up back at the window you started with. previous-window traverses the same cycle, in the reverse order.

This example assumes there are two windows, both displaying the buffer `windows.texi':

 
(selected-window)
     => #<window 56 on windows.texi>
(next-window (selected-window))
     => #<window 52 on windows.texi>
(next-window (next-window (selected-window)))
     => #<window 56 on windows.texi>

Function: previous-window &optional window minibuf which-frames which-devices
This function returns the window preceding window in the cyclic ordering of windows. The other arguments specify which windows to include in the cycle, as in next-window.

Command: other-window count &optional which-frames which-devices
This function selects the countth following window in the cyclic order. If count is negative, then it selects the -countth preceding window. It returns nil.

In an interactive call, count is the numeric prefix argument.

The other arguments specify which windows to include in the cycle, as in next-window.

Function: walk-windows function &optional minibuf which-frames which-devices
This function cycles through all windows, calling function once for each window with the window as its sole argument.

The other arguments specify which windows to cycle through, as in next-window.


[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [Top] [Contents] [Index] [ ? ]

38.6 Buffers and Windows

This section describes low-level functions to examine windows or to display buffers in windows in a precisely controlled fashion. See section 38.7 Displaying Buffers in Windows, for related functions that find a window to use and specify a buffer for it. The functions described there are easier to use than these, but they employ heuristics in choosing or creating a window; use these functions when you need complete control.

Function: set-window-buffer window buffer-or-name &optional norecord
This function makes window display buffer-or-name as its contents. buffer-or-name can be a buffer or a buffer name.

With non-nil optional argument norecord, do not modify the global or per-frame buffer ordering.

This function returns nil.

 
(set-window-buffer (selected-window) "foo")
     => nil

Variable: buffer-display-count
This variable, local to a given buffer, reflects the number of times XEmacs has displayed the buffer in a window.

Function: window-buffer &optional window
This function returns the buffer that window is displaying. If window is omitted, this function returns the buffer for the selected window.

 
(window-buffer)
     => #<buffer windows.texi>

Function: get-buffer-window buffer-or-name &optional which-frames which-devices
This function returns a window currently displaying buffer-or-name, or nil if there is none. If there are several such windows, then the function returns the first one in the cyclic ordering of windows, starting from the selected window. See section 38.5 Cyclic Ordering of Windows.

The remaining arguments control which windows to consider. They have the same meaning as for next-window.

Variable: buffer-display-time
This variable records the time at which a buffer was last made visible in a window. It is always local in each buffer; each time set-window-buffer is called, it sets this variable to (current-time) in the specified buffer (see section 57.5 Time of Day). When a buffer is first created, buffer-display-time starts out with the value nil.


[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [Top] [Contents] [Index] [ ? ]

38.7 Displaying Buffers in Windows

In this section we describe convenient functions that choose a window automatically and use it to display a specified buffer. These functions can also split an existing window in certain circumstances. We also describe variables that parameterize the heuristics used for choosing a window. See section 38.6 Buffers and Windows, for low-level functions that give you more precise control.

Do not use the functions in this section in order to make a buffer current so that a Lisp program can access or modify it; they are too drastic for that purpose, since they change the display of buffers in windows, which is gratuitous and will surprise the user. Instead, use set-buffer (see section 37.2 The Current Buffer) and save-excursion (see section 41.3 Excursions), which designate buffers as current for programmed access without affecting the display of buffers in windows.

Command: switch-to-buffer buffer-or-name &optional norecord
This function makes buffer-or-name the current buffer, and also displays the buffer in the selected window. This means that a human can see the buffer and subsequent keyboard commands will apply to it. Contrast this with set-buffer, which makes buffer-or-name the current buffer but does not display it in the selected window. See section 37.2 The Current Buffer.

If buffer-or-name does not identify an existing buffer, then a new buffer by that name is created. The major mode for the new buffer is set according to the variable default-major-mode. See section 33.1.3 How XEmacs Chooses a Major Mode.

Normally the specified buffer is put at the front of the buffer list. This affects the operation of other-buffer. However, if norecord is non-nil, this is not done. See section 37.8 The Buffer List.

The switch-to-buffer function is often used interactively, as the binding of C-x b. It is also used frequently in programs. It always returns nil.

Command: switch-to-buffer-other-window buffer-or-name
This function makes buffer-or-name the current buffer and displays it in a window not currently selected. It then selects that window. The handling of the buffer is the same as in switch-to-buffer.

The currently selected window is absolutely never used to do the job. If it is the only window, then it is split to make a distinct window for this purpose. If the selected window is already displaying the buffer, then it continues to do so, but another window is nonetheless found to display it in as well.

Function: pop-to-buffer buffer-or-name &optional other-window on-frame
This function makes buffer-or-name the current buffer and switches to it in some window, preferably not the window previously selected. The "popped-to" window becomes the selected window within its frame.

If the variable pop-up-frames is non-nil, pop-to-buffer looks for a window in any visible frame already displaying the buffer; if there is one, it returns that window and makes it be selected within its frame. If there is none, it creates a new frame and displays the buffer in it.

If pop-up-frames is nil, then pop-to-buffer operates entirely within the selected frame. (If the selected frame has just a minibuffer, pop-to-buffer operates within the most recently selected frame that was not just a minibuffer.)

If the variable pop-up-windows is non-nil, windows may be split to create a new window that is different from the original window. For details, see 38.8 Choosing a Window for Display.

If other-window is non-nil, pop-to-buffer finds or creates another window even if buffer-or-name is already visible in the selected window. Thus buffer-or-name could end up displayed in two windows. On the other hand, if buffer-or-name is already displayed in the selected window and other-window is nil, then the selected window is considered sufficient display for buffer-or-name, so that nothing needs to be done.

All the variables that affect display-buffer affect pop-to-buffer as well. See section 38.8 Choosing a Window for Display.

If buffer-or-name is a string that does not name an existing buffer, a buffer by that name is created. The major mode for the new buffer is set according to the variable default-major-mode. See section 33.1.3 How XEmacs Chooses a Major Mode.

If on-frame is non-nil, it is the frame to pop to this buffer on.

An example use of this function is found at the end of 56.9.2 Process Filter Functions.

Command: replace-buffer-in-windows buffer &optional which-frames which-devices
This function replaces buffer with some other buffer in all windows displaying it. The other buffer used is chosen with other-buffer. In the usual applications of this function, you don't care which other buffer is used; you just want to make sure that buffer is no longer displayed.

The optional arguments which-frames and which-devices have the same meaning as with delete-windows-on.

This function returns nil.


[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [Top] [Contents] [Index] [ ? ]

38.8 Choosing a Window for Display

This section describes the basic facility that chooses a window to display a buffer in---display-buffer. All the higher-level functions and commands use this subroutine. Here we describe how to use display-buffer and how to customize it.

Command: display-buffer buffer-or-name &optional not-this-window override-frame
This command makes buffer-or-name appear in some window, like pop-to-buffer, but it does not select that window and does not make the buffer current. The identity of the selected window is unaltered by this function.

buffer-or-name can be a buffer or the name of one.

If not-this-window is non-nil, it means to display the specified buffer in a window other than the selected one, even if it is already on display in the selected window. This can cause the buffer to appear in two windows at once. Otherwise, if buffer-or-name is already being displayed in any window, that is good enough, so this function does nothing.

If override-frame is non-nil, display on that frame instead of the current frame (or the dedicated frame).

display-buffer returns the window chosen to display buffer-or-name.

Precisely how display-buffer finds or creates a window depends on the variables described below.

A window can be marked as "dedicated" to a particular buffer. Then XEmacs will not automatically change which buffer appears in the window, such as display-buffer might normally do.

Function: window-dedicated-p window
This function returns window's dedicated object, usually t or nil.

Function: set-window-buffer-dedicated window buffer
This function makes window display buffer and be dedicated to that buffer. Then XEmacs will not automatically change which buffer appears in window. If buffer is nil, this function makes window not be dedicated (but doesn't change which buffer appears in it currently).

User Option: pop-up-windows
This variable controls whether display-buffer makes new windows. If it is non-nil and there is only one window, then that window is split. If it is nil, then display-buffer does not split the single window, but uses it whole.

User Option: split-height-threshold
This variable determines when display-buffer may split a window, if there are multiple windows. display-buffer always splits the largest window if it has at least this many lines. If the largest window is not this tall, it is split only if it is the sole window and pop-up-windows is non-nil.

User Option: pop-up-frames
This variable controls whether display-buffer makes new frames. If it is non-nil, display-buffer looks for an existing window already displaying the desired buffer, on any visible frame. If it finds one, it returns that window. Otherwise it makes a new frame. The variables pop-up-windows and split-height-threshold do not matter if pop-up-frames is non-nil.

If pop-up-frames is nil, then display-buffer either splits a window or reuses one.

See section 39. Frames, for more information.

Variable: pop-up-frame-function
This variable specifies how to make a new frame if pop-up-frames is non-nil.

Its value should be a function of no arguments. When display-buffer makes a new frame, it does so by calling that function, which should return a frame. The default value of the variable is a function that creates a frame using properties from pop-up-frame-plist.

Variable: pop-up-frame-plist
This variable holds a plist specifying frame properties used when display-buffer makes a new frame. See section 39.2 Frame Properties, for more information about frame properties.

Variable: special-display-buffer-names
A list of buffer names for buffers that should be displayed specially. If the buffer's name is in this list, display-buffer handles the buffer specially.

By default, special display means to give the buffer a dedicated frame.

If an element is a list, instead of a string, then the CAR of the list is the buffer name, and the rest of the list says how to create the frame. There are two possibilities for the rest of the list. It can be a plist, specifying frame properties, or it can contain a function and arguments to give to it. (The function's first argument is always the buffer to be displayed; the arguments from the list come after that.)

Variable: special-display-regexps
A list of regular expressions that specify buffers that should be displayed specially. If the buffer's name matches any of the regular expressions in this list, display-buffer handles the buffer specially.

By default, special display means to give the buffer a dedicated frame.

If an element is a list, instead of a string, then the CAR of the list is the regular expression, and the rest of the list says how to create the frame. See above, under special-display-buffer-names.

Variable: special-display-function
This variable holds the function to call to display a buffer specially. It receives the buffer as an argument, and should return the window in which it is displayed.

The default value of this variable is special-display-popup-frame.

Function: special-display-popup-frame buffer
This function makes buffer visible in a frame of its own. If buffer is already displayed in a window in some frame, it makes the frame visible and raises it, to use that window. Otherwise, it creates a frame that will be dedicated to buffer.

This function uses an existing window displaying buffer whether or not it is in a frame of its own; but if you set up the above variables in your init file, before buffer was created, then presumably the window was previously made by this function.

User Option: special-display-frame-plist
This variable holds frame properties for special-display-popup-frame to use when it creates a frame.

Variable: same-window-buffer-names
A list of buffer names for buffers that should be displayed in the selected window. If the buffer's name is in this list, display-buffer handles the buffer by switching to it in the selected window.

Variable: same-window-regexps
A list of regular expressions that specify buffers that should be displayed in the selected window. If the buffer's name matches any of the regular expressions in this list, display-buffer handles the buffer by switching to it in the selected window.

Variable: display-buffer-function
This variable is the most flexible way to customize the behavior of display-buffer. If it is non-nil, it should be a function that display-buffer calls to do the work. The function should accept two arguments, the same two arguments that display-buffer received. It should choose or create a window, display the specified buffer, and then return the window.

This hook takes precedence over all the other options and hooks described above.

A window can be marked as "dedicated" to its buffer. Then display-buffer does not try to use that window.

Function: window-dedicated-p window
This function returns t if window is marked as dedicated; otherwise nil.

Function: set-window-dedicated-p window flag
This function marks window as dedicated if flag is non-nil, and nondedicated otherwise.


[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [Top] [Contents] [Index] [ ? ]

38.9 Windows and Point

Each window has its own value of point, independent of the value of point in other windows displaying the same buffer. This makes it useful to have multiple windows showing one buffer.

As far as the user is concerned, point is where the cursor is, and when the user switches to another buffer, the cursor jumps to the position of point in that buffer.

Function: window-point &optional window
This function returns the current position of point in window. For a non-selected window, this is the value point would have (in that window's buffer) if that window were selected.

When window is the selected window and its buffer is also the current buffer, the value returned is the same as the value of point in that buffer.

Strictly speaking, it would be more correct to return the "top-level" value of point, outside of any save-excursion forms. But that value is hard to find.

Function: set-window-point window position
This function positions point in window at position position in window's buffer.

Function: current-pixel-row &optional window pos
Function: current-pixel-column &optional window pos
The function, current-pixel-row, returns the vertical location, in pixels, of the point pos within the specified window; similarly, current-pixel-column returns the corresponding horizontal location. The position returned is that of the upper-left corner of the cursor, and is relative to the upper-left location of the window. If window is nil, the function uses the selected window. If pos is nil, the value of window-point is used.

Note that the coordinates are relative to the current XEmacs window, and are not relative to the XEmacs X11 window. To obtain the coordinates relative to the X11 window, you must also take into account the spacings of any menubars, gutters, toolbars, margins, etc., as well as any window offsets. The function, window-pixel-edges (see section 38.14 The Position of a Window), can be used to help calculate the location relative to the frame.

Important note: in order for these functions to return a correct, non-nil value, two criteria must be satisfied:

If one of these is not done, the return value may be incorrect, even if it is non-nil.


[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [Top] [Contents] [Index] [ ? ]

38.10 The Window Start Position

Each window contains a marker used to keep track of a buffer position that specifies where in the buffer display should start. This position is called the display-start position of the window (or just the start). The character after this position is the one that appears at the upper left corner of the window. It is usually, but not inevitably, at the beginning of a text line.

Function: window-start &optional window
This function returns the display-start position of window window. If window is nil, the selected window is used. For example,

 
(window-start)
     => 7058

When you create a window, or display a different buffer in it, the display-start position is set to a display-start position recently used for the same buffer, or 1 if the buffer doesn't have any.

For a realistic example, see the description of count-lines in 41.2.4 Motion by Text Lines.

Function: window-end &optional window guarantee
This function returns the position of the end of the display in window window. If window is nil, the selected window is used.

Simply changing the buffer text or setting window-start does not update the value that window-end returns. The value is updated only when Emacs redisplays and redisplay actually finishes.

If the last redisplay of window was preempted, and did not finish, Emacs does not know the position of the end of display in that window. In that case, this function returns a value that is not correct. In a future version, window-end will return nil in that case.

If optional arg guarantee is non-nil, the return value is guaranteed to be the same as window-end would return at the end of the next full redisplay assuming nothing else changes in the meantime. This function is potentially much slower with this flag set.

Function: set-window-start window position &optional noforce
This function sets the display-start position of window to position in window's buffer. It returns position.

The display routines insist that the position of point be visible when a buffer is displayed. Normally, they change the display-start position (that is, scroll the window) whenever necessary to make point visible. However, if you specify the start position with this function using nil for noforce, it means you want display to start at position even if that would put the location of point off the screen. If this does place point off screen, the display routines move point to the left margin on the middle line in the window.

For example, if point is 1 and you set the start of the window to 2, then point would be "above" the top of the window. The display routines will automatically move point if it is still 1 when redisplay occurs. Here is an example:

 
;; Here is what `foo' looks like before executing
;;   the set-window-start expression.

---------- Buffer: foo ----------
-!-This is the contents of buffer foo.
2
3
4
5
6
---------- Buffer: foo ----------

(set-window-start
 (selected-window)
 (1+ (window-start)))
=> 2

;; Here is what `foo' looks like after executing
;;   the set-window-start expression.
---------- Buffer: foo ----------
his is the contents of buffer foo.
2
3
-!-4
5
6
---------- Buffer: foo ----------

If noforce is non-nil, and position would place point off screen at the next redisplay, then redisplay computes a new window-start position that works well with point, and thus position is not used.

Function: pos-visible-in-window-p &optional position window
This function returns t if position is within the range of text currently visible on the screen in window. It returns nil if position is scrolled vertically out of view. The argument position defaults to the current position of point; window, to the selected window. Here is an example:

 
(or (pos-visible-in-window-p
     (point) (selected-window))
    (recenter 0))

The pos-visible-in-window-p function considers only vertical scrolling. If position is out of view only because window has been scrolled horizontally, pos-visible-in-window-p returns t. See section 38.12 Horizontal Scrolling.


[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [Top] [Contents] [Index] [ ? ]

38.11 Vertical Scrolling

Vertical scrolling means moving the text up or down in a window. It works by changing the value of the window's display-start location. It may also change the value of window-point to keep it on the screen.

In the commands scroll-up and scroll-down, the directions "up" and "down" refer to the motion of the text in the buffer at which you are looking through the window. Imagine that the text is written on a long roll of paper and that the scrolling commands move the paper up and down. Thus, if you are looking at text in the middle of a buffer and repeatedly call scroll-down, you will eventually see the beginning of the buffer.

Some people have urged that the opposite convention be used: they imagine that the window moves over text that remains in place. Then "down" commands would take you to the end of the buffer. This view is more consistent with the actual relationship between windows and the text in the buffer, but it is less like what the user sees. The position of a window on the terminal does not move, and short scrolling commands clearly move the text up or down on the screen. We have chosen names that fit the user's point of view.

The scrolling functions (aside from scroll-other-window) have unpredictable results if the current buffer is different from the buffer that is displayed in the selected window. See section 37.2 The Current Buffer.

Command: scroll-up &optional lines
This function scrolls the text in the selected window upward lines lines. If lines is negative, scrolling is actually downward.

If lines is nil (or omitted), then the length of scroll is next-screen-context-lines lines less than the usable height of the window (not counting its modeline).

scroll-up returns nil.

Command: scroll-down &optional lines
This function scrolls the text in the selected window downward lines lines. If lines is negative, scrolling is actually upward.

If lines is omitted or nil, then the length of the scroll is next-screen-context-lines lines less than the usable height of the window (not counting its mode line).

scroll-down returns nil.

Command: scroll-other-window &optional lines
This function scrolls the text in another window upward lines lines. Negative values of lines, or nil, are handled as in scroll-up.

You can specify a buffer to scroll with the variable other-window-scroll-buffer. When the selected window is the minibuffer, the next window is normally the one at the top left corner. You can specify a different window to scroll with the variable minibuffer-scroll-window. This variable has no effect when any other window is selected. See section 24.9 Minibuffer Miscellany.

When the minibuffer is active, it is the next window if the selected window is the one at the bottom right corner. In this case, scroll-other-window attempts to scroll the minibuffer. If the minibuffer contains just one line, it has nowhere to scroll to, so the line reappears after the echo area momentarily displays the message "Beginning of buffer".

Variable: other-window-scroll-buffer
If this variable is non-nil, it tells scroll-other-window which buffer to scroll.

User Option: scroll-step
This variable controls how scrolling is done automatically when point moves off the screen. If the value is zero, then redisplay scrolls the text to center point vertically in the window. If the value is a positive integer n, then redisplay brings point back on screen by scrolling n lines in either direction, if possible; otherwise, it centers point. The default value is zero.

User Option: scroll-conservatively
This variable controls how many lines Emacs tries to scroll before recentering. If you set it to a small number, then when you move point a short distance off the screen, XEmacs will scroll the screen just far enough to bring point back on screen, provided that does not exceed scroll-conservatively lines. This variable overrides the redisplay preemption.

User Option: next-screen-context-lines
The value of this variable is the number of lines of continuity to retain when scrolling by full screens. For example, scroll-up with an argument of nil scrolls so that this many lines at the bottom of the window appear instead at the top. The default value is 2.

Command: recenter &optional location window
This function scrolls window (which defaults to the selected window) to put the text where point is located at a specified vertical position within the window.

If location is a nonnegative number, it puts the line containing point location lines down from the top of the window. If location is a negative number, then it counts upward from the bottom of the window, so that -1 stands for the last usable line in the window. If location is a non-nil list, then it stands for the line in the middle of the window.

If location is nil, recenter puts the line containing point in the middle of the window, then clears and redisplays the entire selected frame.

When recenter is called interactively, location is the raw prefix argument. Thus, typing C-u as the prefix sets the location to a non-nil list, while typing C-u 4 sets location to 4, which positions the current line four lines from the top.

With an argument of zero, recenter positions the current line at the top of the window. This action is so handy that some people make a separate key binding to do this. For example,

 
(defun line-to-top-of-window ()
  "Scroll current line to top of window.
Replaces three keystroke sequence C-u 0 C-l."
  (interactive)
  (recenter 0))

(global-set-key [kp-multiply] 'line-to-top-of-window)


[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [Top] [Contents] [Index] [ ? ]

38.12 Horizontal Scrolling

Because we read English first from top to bottom and second from left to right, horizontal scrolling is not like vertical scrolling. Vertical scrolling involves selection of a contiguous portion of text to display. Horizontal scrolling causes part of each line to go off screen. The amount of horizontal scrolling is therefore specified as a number of columns rather than as a position in the buffer. It has nothing to do with the display-start position returned by window-start.

Usually, no horizontal scrolling is in effect; then the leftmost column is at the left edge of the window. In this state, scrolling to the right is meaningless, since there is no data to the left of the screen to be revealed by it; so this is not allowed. Scrolling to the left is allowed; it scrolls the first columns of text off the edge of the window and can reveal additional columns on the right that were truncated before. Once a window has a nonzero amount of leftward horizontal scrolling, you can scroll it back to the right, but only so far as to reduce the net horizontal scroll to zero. There is no limit to how far left you can scroll, but eventually all the text will disappear off the left edge.

Command: scroll-left &optional count
This function scrolls the selected window count columns to the left (or to the right if count is negative). The return value is the total amount of leftward horizontal scrolling in effect after the change--just like the value returned by window-hscroll (below).

Command: scroll-right &optional count
This function scrolls the selected window count columns to the right (or to the left if count is negative). The return value is the total amount of leftward horizontal scrolling in effect after the change--just like the value returned by window-hscroll (below).

Once you scroll a window as far right as it can go, back to its normal position where the total leftward scrolling is zero, attempts to scroll any farther right have no effect.

Function: window-hscroll &optional window
This function returns the total leftward horizontal scrolling of window---the number of columns by which the text in window is scrolled left past the left margin.

The value is never negative. It is zero when no horizontal scrolling has been done in window (which is usually the case).

If window is nil, the selected window is used.

 
(window-hscroll)
     => 0
(scroll-left 5)
     => 5
(window-hscroll)
     => 5

Function: set-window-hscroll window columns
This function sets the number of columns from the left margin that window is scrolled to the value of columns. The argument columns should be zero or positive; if not, it is taken as zero.

The value returned is columns.

 
(set-window-hscroll (selected-window) 10)
     => 10

Here is how you can determine whether a given position position is off the screen due to horizontal scrolling:

 
(defun hscroll-on-screen (window position)
  (save-excursion
    (goto-char position)
    (and
     (>= (- (current-column) (window-hscroll window)) 0)
     (< (- (current-column) (window-hscroll window))
        (window-width window)))))

[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [Top] [Contents] [Index] [ ? ]

38.13 The Size of a Window

An Emacs window is rectangular, and its size information consists of the height (in lines or pixels) and the width (in character positions or pixels). The modeline is included in the height. The pixel width and height values include scrollbars and margins, while the line/character-position values do not.

Note that the height in lines, and the width in characters, are determined by dividing the corresponding pixel value by the height or width of the default font in that window (if this is a variable-width font, the average width is used). The resulting values may or may not represent the actual number of lines in the window, or the actual number of character positions in any particular line, esp. if there are pixmaps or various different fonts in the window.

The following functions return size information about a window:

Function: window-height &optional window
This function returns the number of lines in window, including its modeline but not including the horizontal scrollbar, if any (this is different from window-pixel-height). If window is nil, the function uses the selected window.

 
(window-height)
     => 40
(split-window-vertically)
     => #<window on "windows.texi" 0x679b>
(window-height)
     => 20

Function: window-width &optional window
This function returns the number of columns in window, not including any left margin, right margin, or vertical scrollbar (this is different from window-pixel-width). If window is nil, the function uses the selected window.

 
(window-width)
     => 80
(window-height)
     => 40
(split-window-horizontally)
     => #<window on "windows.texi" 0x7538>
(window-width)
     => 39

Note that after splitting the window into two side-by-side windows, the width of each window is less the half the width of the original window because a vertical scrollbar appeared between the windows, occupying two columns worth of space. Also, the height shrunk by one because horizontal scrollbars appeared that weren't there before. (Horizontal scrollbars appear only when lines are truncated, not when they wrap. This is usually the case for horizontally split windows but not for full-frame windows. You can change this using the variables truncate-lines and truncate-partial-width-windows.)

Function: window-pixel-height &optional window
This function returns the height of window in pixels, including its modeline and horizontal scrollbar, if any. If window is nil, the function uses the selected window.

 
(window-pixel-height)
     => 600
(split-window-vertically)
     => #<window on "windows.texi" 0x68a6>
(window-pixel-height)
     => 300

Function: window-pixel-width &optional window
This function returns the width of window in pixels, including any left margin, right margin, or vertical scrollbar that may be displayed alongside it. If window is nil, the function uses the selected window.

 
(window-pixel-width)
     => 735
(window-pixel-height)
     => 600
(split-window-horizontally)
     => #<window on "windows.texi" 0x7538>
(window-pixel-width)
     => 367
(window-pixel-height)
     => 600

Function: window-text-area-pixel-height &optional window
This function returns the height in pixels of the text displaying portion of window, which defaults to the selected window. Unlike window-pixel-height, the space occupied by the modeline and horizontal scrollbar, if any, is not counted.

Function: window-text-area-pixel-width &optional window
This function returns the width in pixels of the text displaying portion of window, which defaults to the selected window. Unlike window-pixel-width, the space occupied by the vertical scrollbar and divider, if any, is not counted.

Function: window-displayed-text-pixel-height &optional window noclipped
This function returns the height in pixels of the text displayed in window, which defaults to the selected window. Unlike window-text-area-pixel-height, any blank space below the end of the buffer is not included. If optional argument noclipped is non-nil, any space occupied by clipped lines will not be included.


[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [Top] [Contents] [Index] [ ? ]

38.14 The Position of a Window

XEmacs provides functions to determine the absolute location of windows within a frame, and the relative location of a window in comparison to other windows in the same frame.

Function: window-pixel-edges &optional window
This function returns a list of the pixel edge coordinates of window. If window is nil, the selected window is used.

The order of the list is (left top right bottom), all elements relative to 0, 0 at the top left corner of window's frame. The element right of the value is one more than the rightmost pixel used by window (including any left margin, right margin, or vertical scrollbar displayed alongside it), and bottom is one more than the bottommost pixel used by window (including any modeline or horizontal scrollbar displayed above or below it). The frame area does not include any frame menubars, toolbars, or gutters that may be displayed; thus, for example, if there is only one window on the frame, the values for left and top will always be 0.

If window is at the upper left corner of its frame, right and bottom are the same as the values returned by (window-pixel-width) and (window-pixel-height) respectively, and left and top are zero.

There is no longer a function window-edges because it does not make sense in a world with variable-width and variable-height lines, as are allowed in XEmacs.

Function: window-highest-p window
This function returns non-nil if window is along the top of its frame.

Function: window-lowest-p window
This function returns non-nil if window is along the bottom of its frame.

Function: window-text-area-pixel-edges &optional window
This function allows one to determine the location of the text-displaying portion of window, which defaults to the selected window, with respect to the top left corner of the window. It returns a list of integer pixel positions (left top right bottom), all relative to (0,0) at the top left corner of the window.


[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [Top] [Contents] [Index] [ ? ]

38.15 Changing the Size of a Window

The window size functions fall into two classes: high-level commands that change the size of windows and low-level functions that access window size. XEmacs does not permit overlapping windows or gaps between windows, so resizing one window affects other windows.

Command: enlarge-window count &optional horizontal window
This function makes the selected window count lines taller, stealing lines from neighboring windows. It takes the lines from one window at a time until that window is used up, then takes from another. If a window from which lines are stolen shrinks below window-min-height lines, that window disappears.

If horizontal is non-nil, this function makes window wider by count columns, stealing columns instead of lines. If a window from which columns are stolen shrinks below window-min-width columns, that window disappears.

If the requested size would exceed that of the window's frame, then the function makes the window occupy the entire height (or width) of the frame.

If count is negative, this function shrinks the window by -count lines or columns. If that makes the window smaller than the minimum size (window-min-height and window-min-width), enlarge-window deletes the window.

If window is non-nil, it specifies a window to change instead of the selected window.

enlarge-window returns nil.

Command: enlarge-window-horizontally columns
This function makes the selected window columns wider. It could be defined as follows:

 
(defun enlarge-window-horizontally (columns)
  (enlarge-window columns t))

Command: enlarge-window-pixels count &optional side window
This function makes the selected window count pixels larger. When called from Lisp, optional second argument side non-nil means to grow sideways count pixels, and optional third argument window specifies the window to change instead of the selected window.

Command: shrink-window count &optional horizontal window
This function is like enlarge-window but negates the argument count, making the selected window smaller by giving lines (or columns) to the other windows. If the window shrinks below window-min-height or window-min-width, then it disappears.

If count is negative, the window is enlarged by -count lines or columns.

If window is non-nil, it specifies a window to change instead of the selected window.

Command: shrink-window-horizontally columns
This function makes the selected window columns narrower. It could be defined as follows:

 
(defun shrink-window-horizontally (columns)
  (shrink-window columns t))

Command: shrink-window-pixels count &optional side window
This function makes the selected window count pixels smaller. When called from Lisp, optional second argument side non-nil means to shrink sideways count pixels, and optional third argument window specifies the window to change instead of the selected window.

The following two variables constrain the window-size-changing functions to a minimum height and width.

User Option: window-min-height
The value of this variable determines how short a window may become before it is automatically deleted. Making a window smaller than window-min-height automatically deletes it, and no window may be created shorter than this. The absolute minimum height is two (allowing one line for the mode line, and one line for the buffer display). Actions that change window sizes reset this variable to two if it is less than two. The default value is 4.

User Option: window-min-width
The value of this variable determines how narrow a window may become before it automatically deleted. Making a window smaller than window-min-width automatically deletes it, and no window may be created narrower than this. The absolute minimum width is one; any value below that is ignored. The default value is 10.

Variable: window-size-change-functions
This variable holds a list of functions to be called if the size of any window changes for any reason. The functions are called just once per redisplay, and just once for each frame on which size changes have occurred.

Each function receives the frame as its sole argument. There is no direct way to find out which windows changed size, or precisely how; however, if your size-change function keeps track, after each change, of the windows that interest you, you can figure out what has changed by comparing the old size data with the new.

Creating or deleting windows counts as a size change, and therefore causes these functions to be called. Changing the frame size also counts, because it changes the sizes of the existing windows.

It is not a good idea to use save-window-excursion in these functions, because that always counts as a size change, and it would cause these functions to be called over and over. In most cases, save-selected-window is what you need here.


[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [Top] [Contents] [Index] [ ? ]

38.16 Window Configurations

A window configuration records the entire layout of a frame--all windows, their sizes, which buffers they contain, what part of each buffer is displayed, and the values of point and the mark. You can bring back an entire previous layout by restoring a window configuration previously saved.

If you want to record all frames instead of just one, use a frame configuration instead of a window configuration. See section 39.11 Frame Configurations.

Function: current-window-configuration &optional frame
This function returns a new object representing the current window configuration of frame, namely the number of windows, their sizes and current buffers, which window is the selected window, and for each window the displayed buffer, the display-start position, and the positions of point and the mark. An exception is made for point in the current buffer, whose value is not saved.

frame defaults to the selected frame.

Function: set-window-configuration configuration
This function restores the configuration of XEmacs's windows and buffers to the state specified by configuration. The argument configuration must be a value that was previously returned by current-window-configuration.

This function always counts as a window size change and triggers execution of the window-size-change-functions. (It doesn't know how to tell whether the new configuration actually differs from the old one.)

Here is a way of using this function to get the same effect as save-window-excursion:

 
(let ((config (current-window-configuration)))
  (unwind-protect
      (progn (split-window-vertically nil)
             ...)
    (set-window-configuration config)))

Macro: save-window-excursion forms...
This macro records the window configuration, executes forms in sequence, then restores the earlier window configuration. The window configuration includes the value of point and the portion of the buffer that is visible. It also includes the choice of selected window. However, it does not include the value of point in the current buffer; use save-excursion if you wish to preserve that.

Don't use this construct when save-selected-window is all you need.

Exit from save-window-excursion always triggers execution of the window-size-change-functions. (It doesn't know how to tell whether the restored configuration actually differs from the one in effect at the end of the forms.)

The return value is the value of the final form in forms. For example:

 
(split-window)
     => #<window 25 on control.texi>
(setq w (selected-window))
     => #<window 19 on control.texi>
(save-window-excursion
  (delete-other-windows w)
  (switch-to-buffer "foo")
  'do-something)
     => do-something
     ;; The frame is now split again.

Function: window-configuration-p object
This function returns t if object is a window configuration.

Primitives to look inside of window configurations would make sense, but none are implemented. It is not clear they are useful enough to be worth implementing.


[ << ] [ >> ]           [Top] [Contents] [Index] [ ? ]

This document was generated by XEmacs Webmaster on August, 3 2012 using texi2html